Scribble pre-processing for Commonmark

example-doc.rkt

#lang cmark-scribble

# This is a test document

1 + 1 is **@+[1 1]**

main.rkt

#lang racket/base

;; This needs to be in a package/collection called "cmark-scribble" to work the example.

(require (for-syntax racket/base)
         commonmark/parse
         commonmark/render/html
         racket/format
         syntax/parse/define)

(provide (except-out (all-from-out racket/base) #%module-begin)
         (rename-out [mb #%module-begin])
         render-html)

(module reader syntax/module-reader
  cmark-scribble
  #:read read-inside
  #:read-syntax read-syntax-inside
  #:whole-body-readers? #t
  (require scribble/reader))

(define-syntax-parse-rule (mb rest ...)
  (#%module-begin
    (define doc (string-append (~a rest) ...))
    (provide doc)
    (module* render #f
      (render-html doc))))

(define (render-html s)
  (write-document-html (string->document s)))

output.txt

$ raco run example-doc.rkt render
<h1>This is a test document</h1><p>1 + 1 is <strong>2</strong></p>