ember.computed.stored.coffee

###
  Creates a computed property that persists into local storage, all
  instances share the same value for the same property.
 
  App.AuthController = Ember.Controller.extend({
    token: Em.computed.stored()
  });
  
  controller = App.__container__.lookup('controller:auth')
  controller.set('token', 'abc123foo456bar')
  
  **Page is reloaded**
  
  controller.get('token')
  -> 'abc123foo456bar'
###
(->
  keyFor = (obj, property) ->
    ns = obj.constructor.toString()
    ns + '.' + Em.String.underscore(property)

  getItem = (obj, property) ->
    key  = keyFor(obj, property)
    data = localStorage.getItem(key)
    if data? then JSON.parse(data).data else null

  setItem = (obj, property, value) ->
    key = keyFor(obj, property)
    if value is null
      localStorage.removeItem(key)
      return
    else
      localStorage.setItem(key, JSON.stringify(
        data: value
      ))
      value
  
  Em.computed.stored = ->
    Em.computed((key, value) ->
      if arguments.length is 1
        getItem(this, key)
      else
        setItem(this, key, value)
        value
    )
  return
)()