gistfile1.clj

(defn neighbours-fn [w h n]
  (letfn [(has-w [i] (not (zero? (rem i w))))
          (pos-w [i] (dec i))
          (has-n [i] (>= i w))
          (pos-n [i] (- i w))
          (has-e [i] (not (zero? (rem (inc i) w))))
          (pos-e [i] (inc i))
          (has-s [i] (< i (* w (dec h))))
          (pos-s [i] (+ i w))]
    (let [pred-pos-m {:w [has-w pos-w]
                      :n [has-n pos-n]
                      :e [has-e pos-e]
                      :s [has-s pos-s]
                      :nw [#(and (has-n %) (has-w %)) (comp pos-w pos-n)]
                      :ne [#(and (has-n %) (has-e %)) (comp pos-e pos-n)]
                      :sw [#(and (has-s %) (has-w %)) (comp pos-w pos-s)]
                      :se [#(and (has-s %) (has-e %)) (comp pos-e pos-s)]}
        j (apply juxt (map #(let [[pred pos] (pred-pos-m %)]
                              (fn [i] (if (pred i) (pos i) -1)))
                           n))]
    (fn [i] (filter (complement neg?) (j i))))))

(defn xy-idx-fn [w]
  (fn [x y]
    (+ (* w y) x)))

(defn idx-xy-fn [w]
  (fn [i]
    (let [y (quot i w)
          x (rem i w)]
      [x y])))