a pattern, in OpenSCAD (unfortunately)

multi-rotating_kite-decorated.scad

// kite for rotation square thingy - scruss, 2025-02

/*
ECHO: "b:", 14.4721
ECHO: "h:", 5.52786
ECHO: "h+b:", 20
ECHO: "(h+b)^2:", 400
ECHO: "b-h:", 8.94427
ECHO: "(b-h)^2:", 80
ECHO: "Part area:", 80
*/

x = 20; // h + b, or (1 + (3 - sqrt(5)) / 2)
b = x / (1 + (3 - sqrt(5)) / 2);
h = x - b; // b * (3 - sqrt(5)) / 2;
echo("b:", b);
echo("h:", h);
echo("h+b:", h + b);
echo("(h+b)^2:", (h + b) ^ 2);
echo("b-h:", b - h);
echo("(b-h)^2:", (b - h) ^ 2);
echo("Part area:", ((h + b) ^ 2) / 5);
// alpha appx 20.9 degrees, but we don't know that yet
c_alpha = b / sqrt(h ^ 2 + b ^ 2);
s_alpha = h / sqrt(h ^ 2 + b ^ 2);
eps = 1e-2;
dx = x;
dy = -(b - h);
gap = floor(x / 20);
a6l = [ 148, 105 ]; // 105 × 148
a5l = [ 210, 148 ]; // 148 × 210

pts = [
  [ 0, 0 ], [ b, 0 ], [ b, h ],
  [ b * (c_alpha ^ 2 - s_alpha ^ 2), 2 * b *s_alpha *c_alpha ]
];

module scribe() { circle(d = gap, $fn = 36); }

module kitegaps() {
  for (i = [1:floor(b / (2 * gap)) - 1]) {
    union() {
      hull() {
        translate([ i * 2 * gap + gap / 2, 0 ]) scribe();
        translate([
          i * 2 * gap + gap / 2, s_alpha * (i * 2 * gap + gap / 2)
        ]) scribe();
      }
      hull() {
        translate([
          i * 2 * gap + gap / 2, s_alpha * (i * 2 * gap + gap / 2)
        ]) scribe();
        translate([
          cos(2 * asin(s_alpha)) * (i * 2 * gap + gap / 2),
          sin(2 * asin(s_alpha)) * (i * 2 * gap + gap / 2)
        ]) scribe();
      }
    }
  }
}

module plainkite() { offset(delta = -gap / 2) polygon(pts); }
// module kite() { polygon(pts); }

module kite() {
  difference() {
    plainkite();
    kitegaps();
  }
}

module outl(s) {
  difference() {
    offset(delta = s / 2) children();
    offset(delta = -s / 2) children();
  }
}

module hsquare() {
  difference() {
    offset(delta = -gap / 2) square(b - h, center = true);
    union() {
      outl(gap) square(15 * (b - h) / 24, center = true);
      outl(gap) square((b - h) / 4, center = true);
    }
  }
}

module ssquare() { hsquare(); }

module fourkite() {
  translate([ 0, 0 ]) kite();
  translate([ -h, b ]) rotate(-90) kite();
  translate([ b - h, b + h ]) rotate(-180) kite();
  translate([ b, h ]) rotate(-270) kite();
  translate([ x / 2 - h, x / 2 ]) rotate(2 * acos(c_alpha)) ssquare();
  translate([ b + (b - h) / 2, 2 * h + (b - h) / 2 ]) hsquare();
}

module line_of_fourkites() {
  for (i = [0:15]) {
    translate([ i * dx, i * dy ]) fourkite();
  }
}

module array_of_kites() {
  //
  rotate(acos(c_alpha))
      translate([ -(x / 2 - h), -x / 2 ]) for (j = [0:11]) {
    translate([ j * (-dx - dy), j * (dx - dy) ]) line_of_fourkites();
  }
}

scale(a5l.x / a6l.x) intersection() {
  array_of_kites();
  square(a6l);
}

multi-rotating_kite-decorated.svg