core.async debounce

debounce.cljs

(defn debounce [in ms]
  (let [out (chan)]
    (go-loop [last-val nil]
      (let [val (if (nil? last-val) (<! in) last-val)
            timer (timeout ms)
            [new-val ch] (alts! [in timer])]
        (condp = ch
          timer (do (>! out val) (recur nil))
          in (recur new-val))))
    out))

nice, just one comment, this implementation has one issue, that is when you close the in channel it gets into an infinite loop by recurring with new-val as nil all the time, the fix is simple, just check the value when receiving from in:

(defn debounce [in ms]
  (let [out (chan)]
    (go-loop [last-val nil]
      (let [val (if (nil? last-val) (<! in) last-val)
            timer (timeout ms)
            [new-val ch] (alts! [in timer])]
        (condp = ch
          timer (do (>! out val) (recur nil))
          in (if new-val (recur new-val)))))
    out))

closing the in when out gets closed:

(defn debounce [in ms]
  (let [out (chan)]
    (go-loop [last-val nil]
             (let [val   (if (nil? last-val) (<! in) last-val)
                   timer (timeout ms)
                   [new-val ch] (alts! [in timer])]
               (condp = ch
                 timer (do (when-not
                             (>! out val)
                             (close! in))
                           (recur nil))
                 in (if new-val (recur new-val)))))
    out))