3d printed box with textured side for strength when printing in vase mode

vase_box.scad

$fn=50;

x_dim = (5.625 * 25.4) / 2;
y_dim = 2.365 * 25.4;
height = 1.625 * 25.4;
radius = 0.375 * 25.4;

corrugated_width = 4.5;
corrugated_depth = 1.5;

a = x_dim - 2*radius;
b = y_dim - 2*radius;

Na = floor(a / (2*corrugated_width));
Nb = floor(b / (2*corrugated_width));

module x_corrugation() {
    translate([-corrugated_width/2,0,0]) {
        translate([(-2*corrugated_width*Na)/2,0,0]) {
            for(i=[0:corrugated_width:Na*corrugated_width]) {
                translate([2*i, y_dim/2 - corrugated_depth,-1]) {
                    cube([corrugated_width, 2*corrugated_depth, height+2]);
                }
            }
        }
    }
}

module y_corrugation() {
    translate([0,-corrugated_width/2,0]) {
        translate([0,(-2*corrugated_width*Nb)/2,0]) {
            for(i=[0:corrugated_width:Nb*corrugated_width]) {
                translate([x_dim/2 - corrugated_depth, 2*i, -1]) {
                    cube([2*corrugated_depth, corrugated_width, height+2]);
                }
            }
        }
    }
}

difference() {
    translate([radius-x_dim/2, radius-y_dim/2, 0]) {
        minkowski() {
            cube_w = x_dim - 2*radius;
            cube_l = y_dim - 2*radius;
            cube_h = height - 1;
            
            cube([cube_w,cube_l,cube_h]);
            cylinder(r=radius,h=1);
        }
    }
    
    x_corrugation();
    mirror([0,1,0]) x_corrugation();
    
    y_corrugation();
    mirror([1,0,0]) y_corrugation();
}