Triomino Puzzle (PuzzleScript Script)

readme.txt

Play this game by pasting the script in http://www.puzzlescript.net/editor.html

script.txt

title Triomino Puzzle
author Orangemouse275
homepage www.puzzlescript.net
run_rules_on_level_start

========
OBJECTS
========

Background
lightgreen green
11111
01111
11101
11111
10111

Target
darkblue
.....
.000.
.0.0.
.000.
.....

Wall
brown darkbrown
00010
11111
01000
11111
00010

Player
black orange white blue
.000.
.111.
22222
.333.
.3.3.

Crate
orange
00000
0...0
0...0
0...0
00000

Connected_Up
transparent

Connected_Right
transparent

Connected_Down
transparent

Connected_Left
transparent

Init
transparent

=======
LEGEND
=======

. = Background
# = Wall
P = Player and Init
* = Crate
@ = Crate and Target
O = Target

Connected = Connected_Up or Connected_Right or Connected_Down or Connected_Left

=======
SOUNDS
=======

Crate move 36772507

================
COLLISIONLAYERS
================

Background
Target
Player, Wall, Crate
Connected_Up
Connected_Right
Connected_Down
Connected_Left
Init

======
RULES
======

UP [Init] [ Crate | Crate ] -> [Init] [ Crate Connected_Up | Crate Connected_Down ]
RIGHT [Init] [ Crate | Crate ] -> [Init] [ Crate Connected_Right | Crate Connected_Left ]
[Init] -> []

[ > Player | Crate ] -> [ > Player | > Crate ]
[ > Crate | Wall ] -> [ Crate | Wall ]

startloop
UP [ MOVING Crate Connected_Up | STATIONARY Crate ] -> [ MOVING Crate Connected_Up | MOVING Crate ]
+ RIGHT [ MOVING Crate Connected_Right | STATIONARY Crate ] -> [ MOVING Crate Connected_Right | MOVING Crate ]
+ DOWN[ MOVING Crate Connected_Down | STATIONARY Crate ] -> [ MOVING Crate Connected_Down | MOVING Crate ]
+ LEFT [ MOVING Crate Connected_Left | STATIONARY Crate ] -> [ MOVING Crate Connected_Left | MOVING Crate ]
endloop

[ > Crate | STATIONARY Crate ] -> [ STATIONARY Crate | STATIONARY Crate ]
[ > Crate | Wall ] -> [ STATIONARY Crate | Wall ]

startloop
UP [ STATIONARY Crate Connected_Up | MOVING Crate ] -> [ STATIONARY Crate Connected_Up | STATIONARY Crate ]
+ RIGHT [ STATIONARY Crate Connected_Right | MOVING Crate ] -> [ STATIONARY Crate Connected_Right | STATIONARY Crate ]
+ DOWN[ STATIONARY Crate Connected_Down | MOVING Crate ] -> [ STATIONARY Crate Connected_Down | STATIONARY Crate ]
+ LEFT [ STATIONARY Crate Connected_Left | STATIONARY Crate ] -> [ STATIONARY Crate Connected_Left | STATIONARY Crate ]
endloop


[ MOVING Crate Connected ] -> [ MOVING Crate MOVING Connected ]

==============
WINCONDITIONS
==============

all Target on Crate

=======
LEVELS
=======

##########
##P..O#..#
#...OO#*.#
#...#.**.#
#........#
#.*......#
#.*.**..O#
#.*.*#OOO#
###..#O#O#
##########