My zsh prompt theme. Inspired by themes that oh-my-zsh carry on.

shahin.zsh-theme.sh

# Determine the time since last commit. If branch is clean,
# use a neutral color, otherwise colors will vary according to time.
function git_time_since_commit() {
    if git rev-parse --git-dir > /dev/null 2>&1; then
        # Only proceed if there is actually a commit.
        if [[ $(git log 2>&1 > /dev/null | grep -c "^fatal: bad default revision") == 0 ]]; then
            # Get the last commit.
            last_commit=`git log --pretty=format:'%at' -1 2> /dev/null`
            now=`date +%s`
            seconds_since_last_commit=$((now-last_commit))

            # Totals
            MINUTES=$((seconds_since_last_commit / 60))
            HOURS=$((seconds_since_last_commit/3600))

            # Sub-hours and sub-minutes
            DAYS=$((seconds_since_last_commit / 86400))
            SUB_HOURS=$((HOURS % 24))
            SUB_MINUTES=$((MINUTES % 60))

            if [[ -n $(git status -s 2> /dev/null) ]]; then
                if [ "$MINUTES" -gt 30 ]; then
                    COLOR="$ZSH_THEME_GIT_TIME_SINCE_COMMIT_LONG"
                elif [ "$MINUTES" -gt 10 ]; then
                    COLOR="$ZSH_THEME_GIT_TIME_SHORT_COMMIT_MEDIUM"
                else
                    COLOR="$ZSH_THEME_GIT_TIME_SINCE_COMMIT_SHORT"
                fi
            else
                COLOR="$ZSH_THEME_GIT_TIME_SINCE_COMMIT_NEUTRAL"
            fi

            if [ "$HOURS" -gt 24 ]; then
                echo "%{$fg_bold[red]%}[%{$reset_color%}$COLOR${DAYS}d${SUB_HOURS}h${SUB_MINUTES}m%{$reset_color%}%{$fg_bold[red]%}]"
            elif [ "$MINUTES" -gt 60 ]; then
                echo "%{$fg_bold[red]%}[%{$reset_color%}$COLOR${HOURS}h${SUB_MINUTES}m%{$reset_color%}%{$fg_bold[red]%}]"
            else
                echo "%{$fg_bold[red]%}[%{$reset_color%}$COLOR${MINUTES}m%{$reset_color%}%{$fg_bold[red]%}]"
            fi
        else
            COLOR="$ZSH_THEME_GIT_TIME_SINCE_COMMIT_NEUTRAL"
            echo "[$COLOR~]"
        fi
    fi
}



ZSH_THEME_GIT_PROMPT_PREFIX="%{$fg_bold[red]%}[%{$fg_bold[yellow]%}"
ZSH_THEME_GIT_PROMPT_SUFFIX="%{$fg_bold[red]%}]%{$reset_color%}"
ZSH_THEME_GIT_PROMPT_DIRTY=" %{$fg_bold[red]%}⚡%{$reset_color%}"

# Format for git_prompt_long_sha() and git_prompt_short_sha()
ZSH_THEME_GIT_PROMPT_SHA_BEFORE="[%{$fg_bold[yellow]%}"
ZSH_THEME_GIT_PROMPT_SHA_AFTER="%{$reset_color%}%{$fg_bold[red]%}]%{$reset_color%}"

# Colors vary depending on time lapsed.
ZSH_THEME_GIT_TIME_SINCE_COMMIT_SHORT="%{$fg[green]%}"
ZSH_THEME_GIT_TIME_SHORT_COMMIT_MEDIUM="%{$fg[yellow]%}"
ZSH_THEME_GIT_TIME_SINCE_COMMIT_LONG="%{$fg[red]%}"
ZSH_THEME_GIT_TIME_SINCE_COMMIT_NEUTRAL="%{$fg[cyan]%}"

PROMPT=$'%{$fg[red]%}┌[%{$fg_bold[yellow]%}%n%{$reset_color%}%{$fg[red]%}@%{$fg_bold[yellow]%}%m%{$reset_color%}%{$fg[red]%}][%{$fg_bold[yellow]%}%~%{$reset_color%}%{$fg[red]%}]
%{$fg[red]%}└%(?,,%{$fg[red]%}[%{$fg_bold[yellow]%}%?%{$reset_color%}%{$fg[red]%}])>%{$reset_color%} '
PS2=$' %{$fg[red]%}|>%{$reset_color%} '

RPROMPT='$(git_time_since_commit)$(git_prompt_short_sha)$(git_prompt_info)'