Presenter First in Backbone.js

expander.coffee

namespace "MyWidget.Expander", (exports) ->
  template = JST["thingers/widget"]
  exports.expand = (model) ->
    template({
      '$.name': "#{model.get('first_name')} #{model.get('last_name')}"
    })

model.coffee

namespace "MyWidget", (exports) ->
  class exports.Model extends Backbone.Model
    reload: =>
      @fetch
        success: =>
          @trigger "reloaded"

presenter.coffee

namespace "MyWidget", (exports) ->
  class exports.Presenter
    constructor: (@view, @model) ->
      @view.bind "openClicked", =>
        @view.showLoading()
        @model.reload()

      @model.bind "reloaded", =>
        @view.render @model

view.coffee

namespace "MyWidget", (exports) ->
  class exports.View extends Backbone.View
    events:
      "click .open": "openClicked"
      "click .save": "saveClicked"

    openClicked: =>
      @trigger "openClicked"

    saveClicked: =>
      @trigger "saveClicked"

    render: (model) =>
      $(@el).html(MyWidget.Expander.expand(model))

    showLoading: =>
      # code for loading, turn on spinner, hide other stuff etc