PKGBUILD

# $Id: PKGBUILD 80202 2012-11-17 15:45:28Z eric $
# Maintainer: Tobias Powalowski <[email protected]>

pkgname=pmount
pkgver=0.9.23
pkgrel=9
pkgdesc="mount removable devices as normal user"
arch=(i686 x86_64)
license=('GPL2')
url="http://pmount.alioth.debian.org/"
backup=('etc/pmount.allow')
depends=('sysfsutils>=2.0.0-1' 'util-linux')
makedepends=('intltool')
source=(
  https://launchpad.net/ubuntu/oneiric/+source/${pkgname}/${pkgver}-2/+files/${pkgname}_${pkgver}.orig.tar.bz2
  'http://anonscm.debian.org/gitweb/?p=pmount/pmount-debian.git;a=blob_plain;f=debian/completion/pmount'
)

build() {
  export CFLAGS="${CFLAGS} -fPIE -pie"
  export CXXFLAGS="${CXXFLAGS} -fPIE -pie"
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure --prefix=/usr --disable-hal \
    --with-cryptsetup-prog=/usr/sbin/cryptsetup
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -Dm644 ${srcdir}/pmount ${pkgdir}/usr/share/bash-completion/completions/pmount
  mkdir -p ${pkgdir}/media
}
sha1sums=('b77dc9cdcd4a4c839d0d2f7b9e3b185ef40f5572'
          '1b0b9466697c983566dcdff5aa2a12cc6eaf1d5f')
md5sums=('db19f5bf3151b1b41705ec7bafa439d3'
         '224f24127f8ab3605de8b9bcb433882f')