PKGBUILD for popcorn-time (binary)

PKGBUILD

# Maintainer: Attila Bukor <r1pp3rj4ck [at] w4it [dot] eu>
# Contributor: Eric Engestrom <aur [at] engestrom [dot] ch>
# Contributor: Iwan Timmer <[email protected]>
# Contributor: Ricardo Band <me [at] xengi [dot] de>
# Contributor: Lucas Saliés Brum <lucas [at] archlinux [dot] com [dot] br>

pkgname=popcorntime
_pkgname=popcorn-time
pkgver=0.3.2
pkgrel=1
pkgdesc="Stream movies from torrents. Skip the downloads. Launch, click, watch."
arch=('x86_64' 'i686')
url="http://popcorntime.io/"
license=('GPL3')
makedepends=('nodejs' 'nodejs-grunt-cli' 'ruby-compass-alpha')
depends=('ttf-ms-fonts')
conflicts=('popcorntime-beta' 'popcorntime-git')
options=('!strip')
install="popcorntime.install"
md5sums=('54b45da143eeb7c344b0a608387fbd1c'
         'efe872f41ed74a706308b4015e4fd82f'
         '9608f35f4cc083a0c36b0f4ef275ab10'
         '5725b4c466ca3726e7a6df52730dacd2')

if [ "$CARCH" = 'i686' ]; then
  _platform=linux32
  _platform2=32
elif [ "$CARCH" = 'x86_64' ]; then
  _platform=linux64
  _platform2=64
fi

source=("http://dl.sistematico.org/pt/src/popcorn-time-${pkgver}-${_platform2}.tar.gz"
        "popcorntime.install"
        "popcorntime.desktop"
        "icon.png")

package() {
  cd "${srcdir}"

  _bpath="${srcdir}/${_pkgname}"

  install -dm755 "${pkgdir}/usr/share/${pkgname}"
  install -dm755 "${pkgdir}/usr/bin"

  # Program
  install -Dm755 "${_bpath}/Popcorn-Time" "${pkgdir}/usr/share/${pkgname}/"
  install -Dm644 "${_bpath}/nw.pak" "${pkgdir}/usr/share/${pkgname}/"
  install -Dm644 "${_bpath}/libffmpegsumo.so" "${pkgdir}/usr/share/${pkgname}/"

  # Link to program
  mkdir -p "${pkgdir}/usr/bin"
  ln -s "/usr/share/${pkgname}/Popcorn-Time" "${pkgdir}/usr/bin/${pkgname}"

  # Desktop file
  install -Dm644 "${srcdir}/popcorntime.desktop" "${pkgdir}/usr/share/applications/popcorntime.desktop"

  # Icon
  install -Dm644 "${srcdir}/icon.png" "${pkgdir}/usr/share/pixmaps/popcorntime.png"
}