Bicep template for requesting app service certificates

certificate.bicep

param domainNames array 
param appServicePlanName string
param location string = resourceGroup().location


resource certificates 'Microsoft.Web/certificates@2020-06-01' = [for domainName in domainNames: {  
  name: domainName
  location: location
  properties: {
    canonicalName: domainName
    serverFarmId: resourceId('Microsoft.Web/serverfarms', appServicePlanName)
    domainValidationMethod: 'http-token'
  }
}]

//output thumbprint1 object = certificates[0]
//output thumbprint2 object = certificates[1]

output thumbprints array = [for i in range(0,length(domainNames)): certificates[i]]

main.bicep

targetScope = 'subscription'
param domainNames array 
param appServicePlanName string
param appServicePlanResourceGroupName string
param appName string
param appResourceGroupName string

module certificate './certificate.bicep' = {
  name: 'certificate'
  scope: resourceGroup(appServicePlanResourceGroupName)
  params: {
    appServicePlanName: appServicePlanName
    domainNames: domainNames
  }
}

// var certs = [
//   certificate.outputs.thumbprint1
//   certificate.outputs.thumbprint2
// ]

module sslbindings './sslbindings.bicep' = {
  name: 'sslbindings'
  scope: resourceGroup(appResourceGroupName)
  params: {
    appName: appName
    certificates: certificate.outputs.thumbprints
  }
}

sslbindings.bicep

param certificates array
param appName string
param location string = resourceGroup().location

resource hostNameSsl 'Microsoft.Web/sites@2020-06-01' = {
  name: appName
  location: location
  properties: {
    hostNameSslStates: [for certificate in certificates: {
      
        name: certificate.properties.canonicalName
        sslState: 'SniEnabled'
        thumbprint: certificate.properties.thumbprint
        toUpdate: true
      }]
  }
}