node.js coffeescript function that returns json tree representation of directory structure

tree.coffee

fs = require 'fs' # node file system module
path = require 'path' # node path module

# returns json tree representation of directory structure
tree = (root) ->
 	 # clean trailing '/'
	root = root.replace /\/+$/ , ""
	# extract tree ring if root exists
	if fs.existsSync root
		ring = fs.lstatSync root
	else
		return 'error: root does not exist'
	# type agnostic info
	info = 
		path: root
		name: path.basename(root)
	# dir	
	if ring.isDirectory()
		info.type = 'folder'
		# execute for each child and call tree recursively
		info.children = fs.readdirSync(root) .map (child) ->
			tree root + '/' + child
	# file
	else if ring.isFile()
		info.type = 'file'
	# link
	else if ring.isSymbolicLink()
		info.type = 'link'
	# other
	else
		info.type = 'unknown'
	# return tree 
	info

# error handling
handle = (e) ->
	return 'error: uncaught exception...'
	
exports.index = (req, res) ->
	try
		res.send tree './test/'
	catch e
		res.send handle e