munge.clj

(ns foo.core
  (:require [clojure.java.io :as io])
  (:import [java.net URL]
           [java.io FileInputStream]
           (javax.xml.bind DatatypeConverter)))


(defn- open-input-stream [^URL url]
  (if-let [user-info (.getUserInfo url)]
    (let [uc (.openConnection url)
          creds (DatatypeConverter/printBase64Binary (.getBytes user-info))
          basic (str "Basic " creds)]
      (.setRequestProperty uc "Authorization" basic)
      (.getInputStream uc))
    (.openStream url)))

(extend URL
  io/IOFactory
  (assoc io/default-streams-impl
    :make-input-stream (fn [^URL x opts]
                         (io/make-input-stream
                          (if (= "file" (.getProtocol x))
                            (FileInputStream. (io/as-file x))
                            (open-input-stream x)) opts))
    :make-output-stream (fn [^URL x opts]
                          (if (= "file" (.getProtocol x))
                            (io/make-output-stream (io/as-file x) opts)
                            (throw (IllegalArgumentException. (str "Can not write to non-file URL <" x ">")))))))