Opportunity Programatic Share - Reinsert Shares after ownership change

OpportunityTrigger.trigger

trigger OpportunityTrigger on Opportunity (before update) {
    Set<Id> ownerChangeOppIds = new Set<Id>();
    for (Opportunity opp : Trigger.new) {
        if(opp.ownerId != Trigger.oldMap.get(opp.Id).OwnerId) {
            ownerChangeOppIds.add(opp.Id);
        }
    }
    if(!ownerChangeOppIds.isEmpty()) {
        String oppShares =  JSON.serialize([select opportunityId, UserOrGroupId, OpportunityAccessLevel, RowCause
                                            from OpportunityShare 
                                            where RowCause='Manual' and opportunityId in: ownerChangeOppIds]);
        OpportunityUtil.reinsertShares(oppShares);
    }   
}

OpportunityUtil.apex

public class OpportunityUtil {
    @future
    public static void reinsertShares(String os) {
        List<OpportunityShare> newOppShares = new List<OpportunityShare>();
        List<OpportunityShare> oppShares = (List<OpportunityShare>)JSON.deserialize(os, List<OpportunityShare>.class);
        for(OpportunityShare oppShare : oppShares) {
            newOppShares.add(new OpportunityShare(
                opportunityId = oppShare.opportunityId,
                UserOrGroupId = oppShare.UserOrGroupId,
                OpportunityAccessLevel = oppShare.OpportunityAccessLevel,
                RowCause = 'Manual'
            ));
        }
        if(! newOppShares.isEmpty()) {
            Database.insert(newOppShares,false);
        }
    }
}