An example base model for Rendr, showing a way to use relations between models.

base.coffee

_ = require('underscore')
RendrBase = require('rendr/shared/base/model')
module.exports = class Base extends RendrBase

  constructor: ->
    super
    @initRelations()

  initRelations: ->
    return unless @relations?
    keys = Object.keys(@relations)
    @updateRelation(key) for key in keys
    keys.forEach (key) =>
      @on "change:#{key}", => @updateRelation(key)

  updateRelation: (key) ->
    relation = @relations[key]
    modelOrCollection = Object.keys(relation)[0]
    path = _.values(relation)[0]
    Constructor = modelUtils.getConstructor(modelOrCollection, path)
    if @has(key)
      property = relation.alias || key
      obj = @[property] = new Constructor(@get(key), parse: true, app: @app)
      obj.store()

reservation.coffee

BaseModel = require('./base')

module.exports = class Reservation extends BaseModel
  @id = 'Reservation'
  jsonKey: 'reservation'

  relations:
    listing: {model: 'Listing'}
    guest: {model: 'User'}
    host: {model: 'User'}

thread.coffee

BaseModel = require('./base')

module.exports = class Thread extends BaseModel
  @id = 'Thread'
  jsonKey: 'thread'
  
  relations:
    posts: 
      collection: 'Messages'
      alias: 'messages'