Tests whether mod_php handles groups in pcre regexes

php-httpd-pcre-jit-test.nix

let testString = "can-use-subgroups"; in
import <nixpkgs/nixos/tests/make-test.nix> {
  name = "php-httpd-pcre-jit-test";
  machine = { config, lib, pkgs, ... }: {
    time.timeZone = "Europe/Copenhagen";
    services.httpd = {
      enable = true;
      adminAddr = "[email protected]";
      extraSubservices = lib.singleton {
        function = f: {
          enablePHP = true;
          phpOptions = "pcre.jit = true";

          extraConfig =
          let
            testRoot = pkgs.writeText "index.php"
            ''
              <?php
                preg_match('/(${testString})/', '${testString}', $result);
                var_dump($result);
              ?>
            '';
          in
            ''
              Alias / ${testRoot}/

              <Directory ${testRoot}>
                Require all granted
              </Directory>
            '';
        };
      };
    };
  };
  testScript = { nodes, ... }:
  ''
    $machine->waitForUnit('httpd.service');
    $machine->succeed('curl -s http://127.0.0.1:80/index.php | grep "${testString}"');
  '';
}