finalizer.coffee

# A reference counter that invokes a callback when it reaches zero.
# Use it to implement after-finished callbacks in asynchronous code.

(exports ? this).Finalizer = class Finalizer
  @from: (finalizerOrCallback) ->
    if finalizerOrCallback instanceof Finalizer
      finalizerOrCallback
    else
      new Finalizer(finalizerOrCallback ? ->)

  constructor: (callback) ->
    @callback = callback
    @count = 0
    @done = no

  increment: ->
    return if @done
    @count += 1

  decrement: ->
    return if @done
    if (@count -= 1) <= 0
      @done = yes
      @callback()

gistfile2.coffee

eachFileInDirectory = (directory, pattern, callback, afterCallback) ->
  pattern ?= /.*/
  finalizer = Finalizer.from(afterCallback)
  finalizer.increment()

  fs.readdir directory, (err, files) ->
    for file in files
      filename = path.join(directory, file)
      finalizer.increment()

      fs.stat filename, (err, stats) ->
        if stats.isDirectory()
          eachFileInDirectory(filename, pattern, callback, finalizer)
          finalizer.decrement()

        else if file.match(pattern)
          callback(filename, finalizer)
          finalizer.decrement()

    finalizer.decrement()