Clojure / RoboVM build.gradle file

build.gradle

buildscript {
    repositories {
        mavenCentral()
        maven { url 'https://oss.sonatype.org/content/repositories/snapshots' }
        maven { url 'http://clojars.org/repo' }
        maven { url 'http://dl.bintray.com/literalice/maven' }
    }
    dependencies {
        classpath 'org.robovm:robovm-gradle-plugin:1.0.1-SNAPSHOT'
        classpath 'clojuresque:clojuresque-base:1.6.0'
        classpath 'com.monochromeroad.gradle-plugins:gradle-aws-s3-sync:0.8'
    }
}

apply plugin: 'java'
apply plugin: 'robovm'
apply plugin: 'clojure-min'

repositories {
    mavenCentral()
    maven { url 'https://oss.sonatype.org/content/repositories/snapshots' }
    maven { url 'http://clojars.org/repo' }
    mavenLocal()
}

ext {
    roboVMVersion = "1.0.1-SNAPSHOT"
}

clojure {
    warnOnReflection = true
    aotCompile = true
}

robovm {
}

task wrapper(type: Wrapper) {
    gradleVersion = "2.2"
}

import com.monochromeroad.gradle.plugin.aws.s3.S3Sync

task syncJars(type: S3Sync) {
    description = "Downloads files from s3 bucket to local directory"
    accessKey "$System.env.LEIN_USERNAME"
    secretKey "$System.env.LEIN_PASSPHRASE"
    configFile "synchronizer.properties"
    // follows the jets3t SDK conventions for action names
    action = 'DOWN'
    from "internal-private-clojars/snapshots"
    into "${System.properties['user.home']}/.m2/repository"
}

dependencies {
    compile "internal-clj-library:internal-clj-library:0.1.0-SNAPSHOT"
    compile "radiator-common:radiator-common:0.1.0-SNAPSHOT"
    compile "org.clojure:clojure:1.7.0-beta1"
    compile "org.robovm:robovm-rt:${roboVMVersion}"
    compile "org.robovm:robovm-cocoatouch:${roboVMVersion}"
    testCompile "junit:junit:4.12"
}