foobar-playlist-style.txt

//--VAR
$puts(brd,28-28-28)
$puts(brd2,70-70-70)
$puts(brd_g1,50-50-50)
$puts(brd_g2,35-35-35)
$puts(transparent, 0-0-0-0)

// Column padding
$puts(padding, 16)

$puts(track_width, 40)
$puts(track_left, $get(padding))

$puts(title_width, 60)
$puts(title_left, $add($get(track_left), $get(track_width), $get(padding)))

$puts(length_width, 60)
$puts(length_left, $sub(%el_width%, $get(padding), $get(length_width)))

$puts(codec_width, 60)
$puts(codec_left, $sub($get(length_left), $get(padding), $get(codec_width)))

$puts(rating_width, 100)
$puts(rating_left, $sub($get(codec_left), $get(padding), $get(rating_width)))

$puts(artist_width, 200)
$puts(artist_left, $sub($get(rating_left), $get(padding), $get(artist_width)))

$puts(badge_color, 0-0-0-32)
$puts(selected_badge_color, 0-0-0-160)

//--PLAYING INDICATOR COLORS
$puts(playing_background, 0-0-0-64)
$puts(p_brd,28-90-189)
$puts(p_g1,92-210-251)
$puts(p_g2,50-164-249)
$puts(p_g3,66-179-249)
$puts(p_g4,37-118-245)

//--TEXT COLORS
$puts(col_tracktex,$if(%el_selected%,15-15-15,$if(%el_isplaying%,54-154-247,230-230-230)))
$puts(col_timetex,$if(%el_selected%,15-15-15,$if(%el_isplaying%,54-154-247,180-180-180)))
$puts(color_shadow,$if(%el_selected%,$get(p_g2),15-15-15))
$puts(col_numtex,$if(%el_selected%,255-255-255,128-128-128))
$puts(color_shadow2,$if(%el_selected%,15-15-15,64-64-64))
$puts(col_rating,230-230-230)

////////////////////////////////////////
// Playing Background
////////////////////////////////////////

$if(%el_isplaying%,
    $drawrect(
        0, 0,
        %el_width%, %el_height%,
        $get(playing_background),
        $get(transparent),
    )
)


////////////////////////////////////////
// Selected Background
////////////////////////////////////////

$if(%el_selected%,
    $gradientrect(
        0, 0,
        %el_width%,
        %el_height%,
        $get(p_g1),
        $get(p_g2),
    )
    $gradientrect(
        1, 1,
        $sub(%el_width%, 2),
        $sub(%el_height%, 2),
        $get(p_g3),
        $get(p_g4),
    )
,)


////////////////////////////////////////
// Track
////////////////////////////////////////

$drawroundrect(
    $get(track_left), 4,
    $get(track_width), $sub(%el_height%, 8),
    $div($sub(%el_height%, 12), 4),
    $div($sub(%el_height%, 12), 4),
    $if(%el_selected%, $get(selected_badge_color), $get(badge_color)),
    $if(%el_selected%, $get(p_g2), 255-255-255-32),
)

$font(Courier New, 10, Regular)

$drawstring($if(%el_isplaying%,►,$if2(%tracknumber%,--)),
    $get(track_left), 1,
    $get(track_width), %el_height%,
    $get(col_numtex),
    hcenter vcenter nowrap
)


////////////////////////////////////////
// Codec
////////////////////////////////////////

$drawroundrect(
    $get(codec_left), 4,
    $get(codec_width),
    $sub(%el_height%, 8),
    $div($sub(%el_height%, 12), 4),
    $div($sub(%el_height%, 12), 4),
    $if(%el_selected%, $get(selected_badge_color), $get(badge_color)),
    $if(%el_selected%, $get(p_g2), 255-255-255-32),
)

$font(Consolas, 10, Regular)

$drawstring($if2(%codec%,--),
    $add($get(codec_left), 1), 0,
    $sub($get(codec_width), 2), %el_height%,
    $get(col_numtex),
    hcenter vcenter nowrap,
    glow:2:0-0-0-64
)


////////////////////////////////////////
// Artist
////////////////////////////////////////

$font(Microsoft JhengHei, 12, Regular)

$puts(artist,$if($not($strcmp(%album artist%,%artist%)),%artist%))
$if($get(artist),
    $drawstring(%artist%,
        $get(artist_left), 0,
        $get(artist_width), %el_height%,
        $get(col_tracktex),
        right vcenter elipchar nowrap
    )
)


////////////////////////////////////////
// Title
////////////////////////////////////////

$drawstring(%title%,
    $get(title_left), 0,
    $sub($if($get(artist), $get(artist_left), $get(rating_left)), $get(title_left)),
    %el_height%,
    $get(col_tracktex),
    left vcenter elipchar nowrap,
)


////////////////////////////////////////
// Rating
////////////////////////////////////////

$font(Arial Unicode MS, 12, Bold)

// If is not streaming
$if(%length%,
    $drawstring($repeat(★, 5),
        $get(rating_left), 0,
        $get(rating_width), %el_height%,
        0-0-0-128,
        left vcenter nowrap aa,
        glow:2:0-0-0-160
    )

    $drawstring($repeat(★, %rating%),
        $get(rating_left), 0,
        $get(rating_width), %el_height%,
        $get(col_rating),
        left vcenter nowrap aa,
    )
)


////////////////////////////////////////
// Length
////////////////////////////////////////

$font(Courier New, 10, Regular)

$drawstring($if2(%length%,--:--),
    $get(length_left), 0,
    $get(length_width), %el_height%,
    $get(col_timetex),
    right vcenter nowrap
)