Mura CMS : Example of how to get the version history of all content items, and how to export version history as a CSV file.

mura-exportVersionHistoryAsCSV.cfm

<cfscript>
	// Example of how to get a CSV report of all content items
	// Drop this under a temp directory under the Mura webroot

	// You could explicitly set this to any siteid you want, if desired
	if ( !IsDefined('$') ) {
		siteid = StructKeyExists(session, 'siteid') ? session.siteid : 'default';
		$ = application.serviceFactory.getBean('$').init(siteid);
	}

	feedBean = $.getBean('feed').setMaxItems(0).setNextN(0);
	it = feedBean.getIterator();
</cfscript>
<cfheader name="Content-Disposition" value="attachment;filename=versionhistory.csv">
<cfcontent type="text/csv">TITLE,STATUS,LASTUPDATE,LASTUPDATEBY
<cfoutput><cfif it.hasNext()><cfloop condition="#it.hasNext()#"><cfset item = it.next() /><cfset itHistory = item.getVersionHistoryIterator() /><cfloop condition="#itHistory.hasNext()#"><cfset hist = itHistory.next() />"#hist.getTitle()#","#hist.getStatus()#","#LSDateFormat(hist.getValue('lastupdate'))# #LSTimeFormat(hist.getValue('lastupdate'))#","#hist.getValue('lastupdateby')#"
</cfloop></cfloop></cfif></cfoutput>

mura-getVersionHistoryInfo.cfm

<cfscript>
	// Example of how to view the Version History of all content items

	feedBean = $.getBean('feed').setMaxItems(0).setNextN(0);
	it = feedBean.getIterator();
</cfscript>

<cfoutput>
	<cfif it.hasNext()>
		<ol>
			<cfloop condition="#it.hasNext()#">
				<cfset item = it.next() />
				<li>
					#item.getTitle()#
					<ul>
						<cfset itHistory = item.getVersionHistoryIterator() />
						<cfloop condition="#itHistory.hasNext()#">
							<cfset hist = itHistory.next() />
							<li>
								#hist.getStatus()# :
								#LSDateFormat(hist.getValue('lastupdate'))# #LSTimeFormat(hist.getValue('lastupdate'))# :
								#hist.getValue('lastupdateby')#
							</li>
						</cfloop>
					</ul>
				</li>
			</cfloop>
		</ol>
	</cfif>
</cfoutput>