rpc_example

// Calculator.qml
import QtQuick 2.0

QtObject {
    property real a
    property real b
    readonly property real sum: a + b
    signal overflow()
    onSumChanged: {
        if(sum > 10000000) overflow()
    }
    function reset() {
        a = 0
        b = 0
    }		
}
//-------------------------------

// server.qml
import QtQuick 2.0
import Rpc 1.0

RpcServer {
    port: 5656
    object: Calculator {}
}
//-------------------------------

// client.qml
import QtQuick 2.0
import QtQuick.Controls 1.0
import QtQuick.Layouts 1.0
import Rpc 1.0

ApplicationWindow {
    title: "client"
    width: 640
    height: 480
    visible: true
    RpcClient {
        id: rpc
        address: "127.0.0.1"
        port: 5656
    }
    readonly property QtObject calculator: rpc.object
    ColumnLayout {
        anchors.centerIn: parent
        RowLayout {
            Binding {
                target: calculator
                property: "a"
                value: txtA.text || 0
            }
            Binding {
                target: calculator
                property: "b"
                value: txtB.text || 0
            }
            TextField {
                id: txtA
            }
            Label {
                text: "+"
            }
            TextField {
                id: txtB
            }       
            Label {
                text: "="
            }   
            TextField {
                text: calculator ? calculator.sum : ""
            }
        }
        Button {
            text: "reset"
            onClicked: if(calculator) calculator.reset()
        }
        Label {
            id: overflowLabel
            Connections {
                target: calculator
                onOverflow: overflowLabel.text = "overflow!"
            }
        }
    }
}