flake.nix

{
  description = "a skeleton haskell flake";
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-20.09";
    flake-utils.url = "github:numtide/flake-utils";
  };
  outputs = { self, nixpkgs, flake-utils, ... }:
    flake-utils.lib.eachDefaultSystem (system:
    let 
      pkgs = import nixpkgs {
        overlays = [ (import ./overlay.nix) ];
        inherit system;
      };
    in {
      defaultPackage = pkgs.haskeleton;
    }) // {
      overlay = import ./overlay.nix;
    };
}

nix-slash-haskeleton.nix

#actually ./nix/haskeleton.nix but gists wont let me put that as the filename
{ mkDerivation, aeson, base, stdenv, text }:
mkDerivation {
  pname = "haskeleton";
  version = "0.1.0.0";
  src = ./.;
  isLibrary = false;
  isExecutable = true;
  executableHaskellDepends = [ aeson base text ];
  license = "unknown";
  hydraPlatforms = stdenv.lib.platforms.none;
}

overlay.nix

final: prev: {
  haskeleton = (import ./release.nix) prev;
}

release.nix

bspkgs: 
let
  dontCheckPackages = [ ];
  doJailbreakPackages = [ ];
  dontHaddockPackages = [ ];
  config = {
    packageOverrides = pkgs: rec {
      haskellPackages =
        let
          generatedOverrides = haskellPackagesNew: haskellPackagesOld:
            let
              toPackage = file: _: {
                name = builtins.replaceStrings [ ".nix" ] [ "" ] file;
                value = haskellPackagesNew.callPackage ( ./. + "/nix/${file}") { };
              };
            in
              pkgs.lib.mapAttrs' toPackage (builtins.readDir ./nix);
          makeOverrides =
            function: names: haskellPackagesNew: haskellPackagesOld:
              let
                toPackage = name: {
                  inherit name;
                  value = function haskellPackagesOld.${name};
                };
              in
                builtins.listToAttrs (map toPackage names);
          composeExtensionsList =
            pkgs.lib.fold pkgs.lib.composeExtensions (_: _: {});
          manualOverrides = haskellPackagesNew: haskellPackagesOld: {
          };
        in
          pkgs.haskellPackages.override {
            overrides = composeExtensionsList [
              generatedOverrides
              (makeOverrides pkgs.haskell.lib.dontCheck dontCheckPackages)
              (makeOverrides pkgs.haskell.lib.doJailbreak doJailbreakPackages)
              (makeOverrides pkgs.haskell.lib.dontHaddock dontHaddockPackages)
              manualOverrides
            ];
          };
    };
  };
  pkgs = import bspkgs.path { inherit config; };
in
  pkgs.haskellPackages.haskeleton