checkstyle.gradle

apply plugin: 'checkstyle'

checkstyle {
    toolVersion = '8.2'
    configFile rootProject.file('checkstyle.xml')
}

afterEvaluate { project ->
    def variants
    if (project.plugins.hasPlugin('com.android.application')) {
        variants = android.applicationVariants
    } else if (project.plugins.hasPlugin('com.android.library')) {
        variants = android.libraryVariants
    } else if (project.plugins.hasPlugin('com.android.feature')) {
        variants = android.featureVariants
    } else {
        return
    }

    def checkstyleTask = project.tasks.create('checkstyle')
    checkstyleTask.group = 'Verification'
    checkstyleTask.description = 'Runs checkstyle on all variants.'
    project.tasks.getByName('check').dependsOn checkstyleTask

    variants.all { variant ->
        def task = project.tasks.create "checkstyle${variant.name.capitalize()}", Checkstyle
        task.group = 'Verification'
        task.description = "Runs checkstyle on the ${variant.name} variant."
        task.dependsOn variant.javaCompile
        task.source variant.javaCompile.source
        task.classpath = project.fileTree(variant.javaCompile.destinationDir)
        task.exclude('**/BuildConfig.java', '**/R.java', '**/Manifest.java')
        task.showViolations true
        checkstyleTask.dependsOn task
    }
}