dan.nix

{ pkgs }:
let env = builtins.getEnv "TELENT_NIXPKGS";
    telentNixpkgsSrc =
      if env != ""
      then
        (builtins.trace "TELENT_NIXPKGS is set, build is impure" env)
      else
        fetchTarball { name = "telent-nixpkgs"; url="https://verisons.telent.net/private-git/telent-nixpkgs.git/snapshot/telent-nixpkgs-master.tar.gz"; };
in {
  isNormalUser = true;
  uid = 1000;
  initialPassword = "foo";
  openssh.authorizedKeys.keys = (import ./authorized-keys.nix);
  extraGroups = [
    "dialout"
    "docker"
    "libvirtd" # not sure if needed
    "scanner"
    "sshd"
    "syncthing"
    "video"
    "wheel"
  ];
  packages =
    let telent-nixpkgs = import telentNixpkgsSrc { inherit (pkgs) system; };
        overlay = self: super: {
          inherit (telent-nixpkgs) alacritty-yml configure-firefox ;
          emacs = telent-nixpkgs.dans-emacs;
        } ;
        xpkgs = pkgs.extend overlay;
    in with xpkgs; [
      nix cacert # nothing else works without these
      alacritty
      cowsay
      emacs
      file
      firefox configure-firefox
      gitFull
      gnumake
      gnupg pinentry-gnome
      irssi
      jq
      mplayer
      mupdf
      notmuch muchsync
      pass
      powertop
      qiv
      tmux
      unzip
      vim
      whois
    ];
}