configuration.nix

{ pkgs, ... }:

{
  imports = [
    ./hello-as-a-service.nix
  ];

  # variante A
#  nixpkgs.overlays = [
#    (final: prev: {
#      hello = prev.hello.overrideAttrs (old: {
#        doCheck = false;
#        prePatch = ''
#          substituteInPlace src/hello.c --replace-fail ", world" ", BWI"
#        '';
#      });
#    })
#  ];

  # variante B
  services.hello.package = pkgs.hello.overrideAttrs (old: {
    doCheck = false;
    prePatch = ''
      substituteInPlace src/hello.c --replace-fail ", world" ", BWI"
    '';
  });

  services.hello.enable = true;

  networking.firewall.enable = true;

  system.stateVersion = "22.11";
}

default.nix

let
  sources = import ./npins;
  pkgs = import sources.nixpkgs { };

  nixosEvaluation = pkgs.nixos [
    ./configuration.nix
    ./qemu-vm.nix
    ./hello-foo.nix
  ];
in

nixosEvaluation.config.system.build.vm

hello-as-a-service.nix

{ config, pkgs, lib, ... }:
let
  cfg = config.services.hello;
in
{
  options.services.hello = {
    enable = lib.mkEnableOption "GNU-Hello as a Service";
    port = lib.mkOption {
      type = lib.types.port;
      default = 8081;
      description = "Port to listen on";
    };
    package = lib.mkOption {
      type = lib.types.package;
      default = pkgs.hello;
    };
  };

  config = lib.mkIf cfg.enable {
    systemd.services.hello = {
      description = "Friendly GNU-Hello as a Service Daemon";
      wantedBy = [ "multi-user.target" ];
      serviceConfig.ExecStart = ''${pkgs.socat}/bin/socat \
        TCP4-LISTEN:${builtins.toString cfg.port},reuseaddr,fork \
        EXEC:${cfg.package}/bin/hello
      '';
    };

  };
}

hello-foo.nix

{ pkgs, lib, ... }: {
  services.hello.package = lib.mkForce (pkgs.hello.overrideAttrs (old: {
    doCheck = false;
    prePatch = ''
      substituteInPlace src/hello.c --replace-fail ", world" ", foobar"
    '';
  }));
}