Untitled PuzzleScript Script

readme.txt

Play this game by pasting the script in http://www.puzzlescript.net/editor.html

script.txt

title wallcat
author thacuber2a03
homepage thacuber.github.io

again_interval 0.06
noaction

verbose_logging

========
objects
========

background 0
transparent

floor .
gray

wall #
darkblue

ice i
blue lightblue
00000
00110
01110
01100
00000

cat
darkgray white pink
0...0
00000
01010
00200
00000

wallupcat
green white pink
00000
00200
01010
00000
0...0

walldowncat
green white pink
0...0
00000
01010
00200
00000

wallleftcat
green white pink
00000
0010.
0200.
0010.
00000

wallrightcat
green white pink
00000
.0100
.0020
.0100
00000

noearswallcat
green white pink
00000
00000
01010
00200
00000

deadcat1
darkgray white pink
0...0
00000
01010
00200
00000

deadcat2
darkgray white pink
0...0
00000
01010
00200
00000

deadcat3
darkgray pink
.....
.0.0.
.000.
.010.
.....

goal1 g
blue lightblue
00000
01110
01010
01110
00000

goal2
lightblue blue
00000
01110
01010
01110
00000

bridge +
brown lightbrown
.000.
01110
01010
01110
.000.

box
brown lightbrown
00000
01110
01010
01110
00000

holebox
darkbrown brown
00000
01110
01010
01110
00000

glassbox
lightblue
00000
00..0
0...0
0..00
00000

brokenglass1
lightblue
.....
.....
..0..
.....
.....

brokenglass2
lightblue blue
...1.
.0.01
.....
1....
...0.

brokenglass3
blue darkblue
1..01
...0.
.....
0...1
...1.

cloud1 c
lightblue
.0.0.
00000
.000.
00000
.0.0.

cloud2
lightblue
0.0.0
.000.
00000
.000.
0.0.0

fallcheck
transparent

temp
transparent

ctemp
transparent

=======
legend
=======

goal = goal1 or goal2
wallcat = wallupcat or walldowncat or wallleftcat or wallrightcat or noearswallcat
deadcat = deadcat1 or deadcat2 or deadcat3
brokenglass = brokenglass1 or brokenglass2 or brokenglass3
cloud = cloud1 or cloud2

player = cat or wallcat
walkable = floor or bridge or goal or holebox
pushable = box or glassbox or cloud
wallrunnable = wall or pushable
justcollidable = ice

p = cat and floor
b = box and floor
- = box and bridge

q = glassbox and floor
x = glassbox and bridge

o = cloud1 and floor
/ = cloud1 and bridge

=======
sounds
=======

wallcat create 22045307
cat create 49009507
player move 3618107
deadcat1 create 93364307
deadcat3 create 15066704
endlevel 72925903
holebox create 59926504
box move 46971707
brokenglass1 create 32507902

================
collisionlayers
================

background
fallcheck temp ctemp
brokenglass
bridge floor goal deadcat holebox
player wallrunnable justcollidable

======
rules
======


late down  [ wallrunnable | cat no walkable | wallrunnable ] -> [ wallrunnable | noearswallcat | wallrunnable ]
late right [ wallrunnable | cat no walkable | wallrunnable ] -> [ wallrunnable | noearswallcat | wallrunnable ]
late up    [ cat no walkable | wallrunnable ] -> [ wallupcat    no walkable | wallrunnable ]
late right [ cat no walkable | wallrunnable ] -> [ wallrightcat no walkable | wallrunnable ]
late down  [ cat no walkable | wallrunnable ] -> [ walldowncat  no walkable | wallrunnable ]
late left  [ cat no walkable | wallrunnable ] -> [ wallleftcat  no walkable | wallrunnable ]

late [ player no walkable | no wallrunnable ] -> [ fallcheck player no walkable | ]
late down  [ wallrunnable | fallcheck player no walkable | wallrunnable ] -> [ wallrunnable | noearswallcat | wallrunnable ]
late right [ wallrunnable | fallcheck player no walkable | wallrunnable ] -> [ wallrunnable | noearswallcat | wallrunnable ]
late up    [ fallcheck player no walkable | wallrunnable ] -> [ wallupcat    no walkable | wallrunnable ]
late right [ fallcheck player no walkable | wallrunnable ] -> [ wallrightcat no walkable | wallrunnable ]
late down  [ fallcheck player no walkable | wallrunnable ] -> [ walldowncat  no walkable | wallrunnable ]
late left  [ fallcheck player no walkable | wallrunnable ] -> [ wallleftcat  no walkable | wallrunnable ]
late [ fallcheck player no walkable ] -> [ deadcat1 no walkable ] again

late [ wallcat walkable ] -> [ cat walkable ]

[ deadcat2 ] -> [ deadcat3 ]
[ deadcat1 ] -> [ deadcat2 ] again

( boxes' shared behavior )

[ > player   | pushable ] -> [ > player   | > pushable ]
[ > pushable | pushable ] -> [ > pushable | > pushable ]

( boxes )

late [ box no walkable ] -> [ holebox ]

( glass boxes )

[ brokenglass2 ] -> [ brokenglass3 ]
[ brokenglass1 ] -> [ brokenglass2 ] again

late [ glassbox no walkable ] -> [ brokenglass1 ] again

( clouds )

[ cloud1 ] -> [ cloud1 ctemp ]
[ cloud2 ] -> [ cloud1 ]
late [ cloud1 ctemp ] -> [ cloud2 ]

( goal )

[ goal1 ] -> [ goal1 temp ]
[ goal2 ] -> [ goal1 ]
late [ goal1 temp ] -> [ goal2 ]

==============
winconditions
==============

all goal on player

=======
levels
=======

message you're a cat

###########
#.........#
#.p.....g.#
#.........#
###########

message you walk on walls

###########
#...000...#
#.p.000.g.#
#...000...#
###########

( message sharp turns bad :[ )

########
#...000#
#.p.000#
#...000#
####...#
####.g.#
####...#
########

message there are bridges

####000####
#...000####
#.p.000####
#...000...#
#...+++...#
#...000...#
####000.g.#
####000...#
####000####

###########
#######...#
#######.g.#
#######...#
#000000000#
#0000+0000#
#000000000#
#...#######
#.p.#######
#...#######
###########

###########
####000...#
####000.g.#
####0+0...#
#####00####
#000000####
#000+++####
#...000####
#.p.00#####
#...00#####
###########

message there are also boxes

message and ice walls

######i####
#.....0...#
#.b.p.0.g.#
#.....0...#
######i####

message boxes push boxes

############
#...########
#.p.0000000#
#...##0###0#
######0###0#
#####i00--0#
#...##0#####
#.g.000#####
#...########
############

message and you can also walk in boxes

##########
#####....#
#####..g.#
#####....#
####+0000#
#....+000#
#.pb.0000#
#....0000#

##########
#####....#
#####..g.#
#####....#
####00000#
#....+000#
#.pb.0000#
#....0000#

message ok sorry, just one more variation

0000....
0000..g.
0000....
00000000
....+000
.pb.0000
....0000

#######00
#...00000
#.p.00-0#
#...0000#
#####000#
#####...#
#####.g.#
#####...#
#########

message don't cut yourself with these!

...
.g.
...
#0#
000
0+0
.q.
.p.
...

####0000####
#...0000####
#.p.0000####
#.b.0000...#
#.q.00++...#
#...0+00...#
#...0000...#
####0000.g.#
####0000...#
####0000####

message cloud is push

00000##
00000g#
00000##
0000000
##000##
#.....#
#.p.o.#
#.....#
#######