wallcat (PuzzleScript Script)

readme.txt

Play this game by pasting the script in http://www.puzzlescript.net/editor.html

script.txt

title wallcat
author thacuber2a03
homepage thacuber.github.io

again_interval 0.06
noaction

verbose_logging

========
objects
========

background 0
transparent

floor .
gray

wall #
darkblue

cat
darkgray white pink
0...0
00000
01010
00200
00000

wallupcat
green white pink
00000
00200
01010
00000
0...0

walldowncat
green white pink
0...0
00000
01010
00200
00000

wallleftcat
green white pink
00000
0010.
0200.
0010.
00000

wallrightcat
green white pink
00000
.0100
.0020
.0100
00000

noearswallcat
green white pink
00000
00000
01010
00200
00000

deadcat1
darkgray white pink
0...0
00000
01010
00200
00000

deadcat2
darkgray white pink
0...0
00000
01010
00200
00000

deadcat3
darkgray pink
.....
.0.0.
.000.
.010.
.....

deadcat4
transparent

deadcat5
gray
.....
.000.
.0.0.
.000.
.....

deadcat6
gray
.0.0.
0...0
.....
0...0
.0.0.

deadcat7
gray
.0.0.
0...0
.....
0...0
.0.0.

goal1 g
blue lightblue
00000
01110
01010
01110
00000

goal2
lightblue blue
00000
01110
01010
01110
00000

bridge +
brown lightbrown
.000.
01110
01010
01110
.000.

box
brown lightbrown
00000
01110
01010
01110
00000

holebox
darkbrown brown
00000
01110
01010
01110
00000

fallcheck
transparent

temp
transparent

=======
legend
=======

goal = goal1 or goal2
wallcat = wallupcat or walldowncat or wallleftcat or wallrightcat or noearswallcat
deadcat = deadcat1 or deadcat2 or deadcat3 or deadcat4 or deadcat5 or deadcat6 or deadcat7
player = cat or wallcat
walkable = floor or bridge or goal or holebox
wallrunnable = wall or box

p = cat and floor
b = box and floor
- = box and bridge

=======
sounds
=======

wallcat create 22045307
cat create 49009507
player move 3618107
deadcat1 create 93364307
deadcat4 destroy 15066704
endlevel 72925903
holebox create 59926504
box move 46971707

================
collisionlayers
================

background
fallcheck temp
bridge floor goal deadcat holebox
player wallrunnable

======
rules
======


late down  [ wallrunnable | cat no walkable | wallrunnable ] -> [ wallrunnable | noearswallcat | wallrunnable ]
late right [ wallrunnable | cat no walkable | wallrunnable ] -> [ wallrunnable | noearswallcat | wallrunnable ]
late up    [ cat no walkable | wallrunnable ] -> [ wallupcat    no walkable | wallrunnable ]
late right [ cat no walkable | wallrunnable ] -> [ wallrightcat no walkable | wallrunnable ]
late down  [ cat no walkable | wallrunnable ] -> [ walldowncat  no walkable | wallrunnable ]
late left  [ cat no walkable | wallrunnable ] -> [ wallleftcat  no walkable | wallrunnable ]

late [ player no walkable | no wallrunnable ] -> [ fallcheck player no walkable | ]
late down  [ wallrunnable | fallcheck player no walkable | wallrunnable ] -> [ wallrunnable | noearswallcat | wallrunnable ]
late right [ wallrunnable | fallcheck player no walkable | wallrunnable ] -> [ wallrunnable | noearswallcat | wallrunnable ]
late up    [ fallcheck player no walkable | wallrunnable ] -> [ wallupcat    no walkable | wallrunnable ]
late right [ fallcheck player no walkable | wallrunnable ] -> [ wallrightcat no walkable | wallrunnable ]
late down  [ fallcheck player no walkable | wallrunnable ] -> [ walldowncat  no walkable | wallrunnable ]
late left  [ fallcheck player no walkable | wallrunnable ] -> [ wallleftcat  no walkable | wallrunnable ]
late [ fallcheck player no walkable ] -> [ deadcat1 no walkable ] again

late [ wallcat walkable ] -> [ cat walkable ]

[ deadcat7 ] -> [ ]
[ deadcat6 ] -> [ deadcat7 ] again
[ deadcat5 ] -> [ deadcat6 ] again
[ deadcat4 ] -> [ deadcat5 ] again
[ deadcat3 ] -> [ deadcat4 ] again
[ deadcat2 ] -> [ deadcat3 ] again
[ deadcat1 ] -> [ deadcat2 ] again

( box )

[ > player | box ] -> [ > player | > box ]
[ > box    | box ] -> [ > box    | > box ]
late [ box no walkable ] -> [ holebox ]

( goal )

[ goal1 ] -> [ goal1 temp ]
[ goal2 ] -> [ goal1 ]
late [ goal1 temp ] -> [ goal2 ]

==============
winconditions
==============

all goal on player

=======
levels
=======

message you're a cat

###########
#.........#
#.p.....g.#
#.........#
###########

message you walk on walls

###########
#...000...#
#.p.000.g.#
#...000...#
###########

( message sharp turns bad :[ )

########
#...000#
#.p.000#
#...000#
####...#
####.g.#
####...#
########

message there are bridges

####000####
#...000####
#.p.000####
#...000####
#...+++...#
####000...#
####000.g.#
####000...#
####000####

###########
#######...#
#######.g.#
#######...#
#000000000#
#0000+0000#
#000000000#
#...#######
#.p.#######
#...#######
###########

###########
####000...#
####000.g.#
####0+0...#
#####00####
#000000####
#000+++####
#...000####
#.p.00#####
#...00#####
###########

message there are also boxes

######0####
#.....0...#
#.b.p.0.g.#
#.....0...#
######0####

message boxes push boxes

############
#...########
#.p.0000000#
#...##0###0#
######0###0#
#####000--0#
#...##0#####
#.g.000#####
#...########
############

message and you can also walk in boxes

##########
#####....#
#####..g.#
#####....#
####+0000#
#....+000#
#.pb.0000#
#....0000#

##########
#####....#
#####..g.#
#####....#
####00000#
#....+000#
#.pb.0000#
#....0000#

#######00
#...00000
#.p.00-0#
#...0000#
#####000#
#####...#
#####.g.#
#####...#
#########