HTTP Request

httpTest.emojic

📦 sockets 🔴
📦 files 🔴

🌮 Represents the HTTP headers and status code 🌮
🐇 🍙 🍇
  🍰 statusCode 🚂
  🍰 headers 🍯🐚🔡

  🐈 🆕 @statusCode 🚂 @headers 🍯🐚🔡 🍇
    🍮 statusCode @statusCode
    🍮 headers @headers
  🍉

  🐖 💂 ➡️ 🍯🐚🔡 🍇
    🍎 headers
  🍉

  🐖 💳 ➡️ 🚂 🍇
    🍎 statusCode
  🍉
🍉

🌮 Represents the destination of an HTTP Request 🌮
🐇 📍 🍇
  🍰 host 🔡
  🍰 path 🔡
  🍰 port 🚂
  🍰 method 🔡
  🍰 headers 🍯🐚🔡
  🍰 body 🍬📇

  🍬🐈 🆕 url 🔡 @method 🔡 🍇
    🍊 ❎🎼  url 🔤http://🔤 🍇
      🍎⚡️
    🍉
    🍮 host 🔤🔤
    🍮 path 🔤🔤
    🍮 port 80
    🍦 protocolless 🔪 url 7 🐔 url
    🍊🍦 :index 🔍 protocolless 🔤:🔤 🍇
      🍦 first/Index 🍺🔍 protocolless 🔤/🔤
      🍮 port 🍺🚂 🔪 protocolless :index ➖ first/Index :index 10
      🍮 host 🔪 protocolless 0 :index
      🍮 path 🔪 protocolless first/Index 🐔 protocolless
    🍉
    🍓 🍇
      🍦 first/Index 🍺🔍 protocolless 🔤/🔤
      🍮 host 🔪 protocolless 0 first/Index
      🍮 path 🔪 protocolless first/Index 🐔 protocolless
    🍉
    🍮 method @method
    🍮 headers 🍯
      🔤Host🔤 host
      🔤User-Agent🔤 🔤Pavel Chekov🔤
    🍆
  🍉

  🐖 💹 string 🔡 ➡️ 🔡 🍇
    🍮 outString 🔤🔤
    🔂 symbol string 🍇
      🍦 code 🚂symbol
      🍊🎉🎊➡️ code 0x31 ⬅️ code 0x39 🎉🎊➡️ code 0x41 ⬅️ code 0x5A 🎉🎊➡️ code 0x61 ⬅️ code 0x7A
        🎉😛 symbol 🔟- 🎉😛 symbol 🔟_ 🎉😛 symbol 🔟. 😛 symbol 🔟~ 🍇
        🍮 outString 📝 outString symbol
      🍉
      🍓 🍇
        🔂 byte 📇🔡symbol 🍇
          🍮 outString 🍪 outString 🔤%🔤 🔡 byte 16 🍪
        🍉
      🍉
    🍉
    🍎 outString
  🍉

  🌮
    Sets the body to the data of the dictionary as `application/x-www-form-urlencoded` and sets
    the according headers.
  🌮
  🐖 📧 dict 🍯🐚🔡 🍇
    🍦 outStrings 🔷🍨🐚🔡🐸
    🐷 headers 🔤Content-Type🔤 🔤application/x-www-form-urlencoded🔤
    🔂 key 🐙 dict 🍇
      🐻 outStrings 🍪 💹🐕 key 🔤=🔤 💹🐕 🍺🐽 dict key 🍪
    🍉
    📩🐕 📇🔷🔡🍨 outStrings 🔤&🔤
  🍉

  🌮 Sets the body to `data` and sets the `Content-Length` header. 🌮
  🐖 📩 data 📇 🍇
    🍮 body data
    🐷 headers 🔤Content-Length🔤 🔡🐔data 10
  🍉

  🌮 Returns the path to the requested resource. 🌮
  🐖 🗺 ➡️ 🔡 🍇
    🍎 path
  🍉

  🌮 Returns the server address. 🌮
  🐖 🏛 ➡️ 🔡 🍇
    🍎 host
  🍉

  🌮 Returns the server port. 🌮
  🐖 🚪 ➡️ 🚂 🍇
    🍎 port
  🍉

  🌮 Returns the HTTP method. 🌮
  🐖 ⛏ ➡️ 🔡 🍇
    🍎 method
  🍉

  🌮 Returns the headers in HTTP format. 🌮
  🐖 💂 ➡️ 🔡 🍇
    🍮 outString 🔤🔤
    🔂 key 🐙 headers 🍇
      🍮 outString 🍪 outString key 🔤: 🔤 🍺🐽 headers key 🔤❌r❌n🔤🍪
    🍉
    🍎 outString
  🍉

  🌮 Returns the body data to be sent to the server. 🌮
  🐖 📨 ➡️ 🍬📇 🍇
    🍎 body
  🍉
🍉

🌮 Represents a connection to an HTTP server. 🌮
🐇 🍕 🍇
  🍰 socket 📞
  🍰 headerOverflowData 🍬📇
  🍰 request 📍

  🐈 🆕 @request 📍 🍇
    🍮 request @request
    🍮 socket 🍺 🔷📞🆕 🏛request 🚪request
  🍉

  🐖 🙈 callback 🍇📇🍉 ➡️ 🍙 🍇
    💬 socket 📇 🍪⛏request 🔤 🔤 🗺request 🔤 HTTP/1.1❌r❌n🔤 💂request 🔤❌r❌n🔤🍪
    🍊🍦 data 📨 request 🍇
      💬 socket data
    🍉
    🍦 response 😊🐕 😮🐕
    🍦 headers 💂response
    🍊 😛 ➗💳response 100 4 🍇
      😀 🔤4xx error🔤
    🍉
    🍋 😛 ➗💳response 100 3 🍇
      🍊 😛 💳response 301 🍇
        🍊🍦 location 🐽 headers 🔤location🔤 🍇
          🍊🍦 nrequest 🔷📍🆕 location ⛏request 🍇
            🍮 request nrequest
            🙈🐕 callback
          🍉
          🍓 🍇
            😀 🍪 🔤Cannot follow 🔤 location 🍪
          🍉
        🍉
        🍓 🍇
          😀 🔤No Location given for 301🔤
        🍉
      🍉
    🍉
    🍋 ❎ 😛 💳response 204 🍇
      🍊🍦 contentLength 🐽 headers 🔤content-length🔤 🍇
        🙃🐕 🍺🚂 contentLength 10 callback
      🍉
      🍓 🍇
        😌🐕 callback
      🍉
    🍉
    🍎 response
  🍉

  🌮 Parses the status-line and message-headers into a 🍙 instance 🌮
  🔐 🐖 😊 message 🔡 ➡️ 🍙 🍇
    🍦 headers 🔫 message 🔤❌r❌n🔤

    🍦 statusLineParts 💣 🍺🐽 headers 0 🔟 🐨 headers 0

    🍦 headerDict 🔷🍯🐚🔡🐸
    🔂 header headers 🍇
      🍦 :index 🍺🔍 header 🔤:🔤
      🐷 headerDict 📪🔪 header 0 :index 🔧🔪 header ➕ :index 1  🐔 header
    🍉

    🍎 🔷🍙🆕 🍺🚂 🍺🐽 statusLineParts 1 10 headerDict
  🍉

  🌮 Receive start-line and headers as string 🌮
  🔐 🐖 😮 ➡️ 🔡 🍇
    🍦 endOfHeaders 📇🔤❌r❌n❌r❌n🔤

    🍮 data 🍺 👂 socket 140
    🔁 👍 🍇
      🍦 index 🔍 data endOfHeaders
      🍊🍦 index index 🍇
        🍊 ◀️ ➕ 4 index 🐔 data 🍇
          🍮 headerOverflowData 🔪 data ➕ 4 index 🐔 data
        🍉
        🍎 🍺🔡 🔪 data 0 index
      🍉
      🍮 data 📝 data 🍺 👂 socket 140
    🍉
    🍎 🔤🔤
  🍉

  🌮
    Receives body with the given length and calls the callback for every
    received data package.
  🌮
  🔐 🐖 🙃 wanted 🚂 callback 🍇📇🍉 🍇
    🍮 stillWanted wanted
    🍊🍦 ov headerOverflowData 🍇
      🍮 stillWanted ➖ stillWanted 🐔 ov
      🍭 callback ov
    🍉
    🔁 ▶️ stillWanted 0 🍇
      🍦 data 🍺 👂 socket stillWanted
      🍮 stillWanted ➖ stillWanted 🐔 data
      🍭 callback data
    🍉
  🍉

  🌮
    Receives body of unknown length and calls the callback for every received
    data package.
  🌮
  🔐 🐖 😌 callback 🍇📇🍉 🍇
    🍊🍦 ov headerOverflowData 🍇
      🍭 callback ov
    🍉
    🔁🍦 data 👂 socket 500 🍇
      🍭 callback data
    🍉
  🍉
🍉

🏁 🍇
  🍦 file 🍺 🔷📄📝 🔤master.zip🔤
  👴 🍦 request 🍺🔷📍🆕🔤http://github.com/emojicode/emojicode/archive/master.zip🔤 🔤GET🔤
  🍦 request 🍺🔷📍🆕🔤http://127.0.0.1/~theo/post.php🔤 🔤POST🔤
  📧 request 🍯 🔤name🔤 🔤Böle Müller🔤 🔤pizza@🔤 🔤Diavolo//🔤 🔤!🔤 🔤3322🔤 🍆
  🙈🔷🍕🆕 request 🍇 d 📇
    🍊🍦 string 🔡d 🍇
      😀 string
    🍉
    🍓 🍇
      😀 🔤!!!Unpritnable!!!🔤
    🍉
    👴 ✏️ file d
  🍉
🍉