MetaCPAN query to find all my distributions which depend on X, where X is some module I've decided to stop using.

my-cpan-rev-deps.pl

#!/usr/bin/env perl

use v5.10;
use strict;
use warnings;

use HTTP::Tiny;
use JSON;

my @fields = qw< distribution version date >;

my ($module, $author) = @ARGV;
$module or die "usage: $0 MODULE [AUTHOR]\n";

my $query = {
	size   => 5000,
	fields => \@fields,
	query  => { match_all => {} },
	filter => {
		and => [
			{ term => { "release.dependency.module" => $module } },
			{ term => { "release.status" => "latest"} },
		]
	}
};

push @{ $query->{filter}{and} }, { term => { "release.author" => $author } }
	if $author;

my $response = "HTTP::Tiny"->new->post(
	"http://api.metacpan.org/v0/release/_search" => {
		content => to_json($query),
		headers => {
			"Content-Type" => "application/json",
		},
	},
);

my $result = from_json($response->{content});

for my $dist (@{ $result->{hits}{hits} }) {
	printf("%s\t%s\t%s\n", map $dist->{fields}{$_}, @fields);
}