blue / green route53 switch.tf

switch.tf

provider "aws" {
  region = "ap-southeast-2"
}

terraform {
  required_version = ">= 0.11.0"

  backend "s3" {
    encrypt = true
  }
}

variable "release_stack" {
  default = "blue"
}

variable "environment" {
  default = "dev"
}

variable "zone" {
  default = "app.com."
}

data "aws_route53_zone" "selected" {
  name = "${var.zone}"
}

locals {
  other_stack = "${var.release_stack == "blue" ? "green" : "blue"}"
}

resource "aws_route53_record" "release" {
  zone_id = "${data.aws_route53_zone.selected.zone_id}"
  name    = ""
  type    = "A"

  alias {
    name                   = "${var.release_stack}.${var.zone}"
    zone_id                = "${data.aws_route53_zone.selected.zone_id}"
    evaluate_target_health = false
  }
}

resource "aws_route53_record" "staging" {
  zone_id = "${data.aws_route53_zone.selected.zone_id}"
  name    = "staging"
  type    = "A"

  alias {
    name                   = "${local.other_stack}.${var.zone}"
    zone_id                = "${data.aws_route53_zone.selected.zone_id}"
    evaluate_target_health = false
  }
}