Perl 6 script to convert dates to ISO8601

date-format-conversion.p6

#!/usr/bin/env perl6

use v6.d;

=begin DESCRIPTION

Given a newline-delimited file of mm/dd/yyyy, write a newline-delimited
file of yyyy-mm-dd.

=end DESCRIPTION

my $in = 'dates.txt'.IO;
my $out = 'dates_iso_8601.txt'.IO;

$out.spurt('');

for $in.lines {
    m/
        $<month> = (\d ** 1..2)
        \/
        $<day> = (\d ** 1..2)
        \/
        $<year> = (\d ** 4)
    /;

    my $date = Date.new($<year>, $<month>, $<day>);

    $out.spurt("{ $date.yyyy-mm-dd }\n", :append);
}

You can easily overwrite STDOUT to your own handle, which will allow you to use say, so you don't have to interpolate into a string. Also, if you're using spurt(... :append), you're opening and closing an OS handle for every spurt. Which is sorta sub-optimal :-)

my $in = 'dates.txt'.IO;
my $*OUT = open('dates_iso_8601.txt',:w);

for $in.lines {
    m/
        $<month> = (\d ** 1..2)
        \/
        $<day> = (\d ** 1..2)
        \/
        $<year> = (\d ** 4)
    /;

    say Date.new($<year>, $<month>, $<day>).yyyy-mm-dd;
}   
$*OUT.close;

Note, unlike Perl 5, handles aren't automatically closed when they go out of scope (but of course, will be by the OS on program exit). So it is better to do this yourself, generally. Or use a LEAVE phaser like:

LEAVE $*OUT.close;

Thank you so much for the code review, @lizmat! I've seen the $*OUT trick but have yet to try it (and didn't think to in this context), so I will check it out. 😎

Thank you especially for all of your hard work on the Perl 6 project; I am a huge fan and I am extremely grateful for how the language is coming along.