Delete unused workspace folders from slaves

jenkins-cleanup-workspace.groovy

import hudson.FilePath
import jenkins.model.Jenkins
import hudson.model.Job

//
// cleans up workspace folders on slaves - removes deleted projects
//
def deleteUnusedWorkspace(FilePath root, String path) {
  if(!root.list())return;
  root.list().sort{child->child.name}.each { child ->
    String fullName = path + child.name

    def item = Jenkins.instance.getItemByFullName(fullName);

    if (item == null) {
      println "Deleting (no such job): '$fullName'"
      child.deleteRecursive()
    } else if (item.class.canonicalName == 'com.cloudbees.hudson.plugins.folder.Folder') {
      deleteUnusedWorkspace(root.child(child.name), "$fullName/")          
    } else if (item instanceof Job && !item.isBuildable()) {
      println "Deleting (job disabled): '$fullName'"
      child.deleteRecursive()
    } else {
      println "Leaving: '$fullName'"
    }
  }
}

for (node in Jenkins.instance.nodes) {
  println "Processing $node.displayName"
  if(node.rootPath) {
    def workspaceRoot = node.rootPath.child("workspace");
    deleteUnusedWorkspace(workspaceRoot, "")
  }
}