Groovy String split() vs tokenize() #groovy

groovySplitVsTokenize.groovy

final List TestCases = [
    '/usr/bin/sh',
    '//usr/bin/sh',
    'usr//bin/sh',
    'usr//bin//sh///',
    '//',
    '/',
    ' /   ',
    '   //    ',
    '   ',
    '',
    null,
    [a: '/'],
]

final String RESULT = '''\

str                      split'/'                 .tokenize'/'

/usr/bin/sh              [, usr, bin, sh]         [usr, bin, sh]
//usr/bin/sh             [, , usr, bin, sh]       [usr, bin, sh]
usr//bin/sh              [usr, , bin, sh]         [usr, bin, sh]
usr//bin//sh///          [usr, , bin, , sh]       [usr, bin, sh]
//                       []                       []
/                        []                       []
 /                       [ ,    ]                 [ ,    ]
   //                    [   , ,     ]            [   ,     ]
                         [   ]                    [   ]
                         []                       []
null                     null                     null
[a:/]                    null                     null

'''

final List HEADER = [ 'str', $/split'/'/$, $/.tokenize'/'/$ ]


println toPrintedString(*HEADER)
println()
TestCases.each {
    List s, t

    try { s = it.split'/' } catch(e) {}
    try { t = it.tokenize'/' } catch(e) {}

    println toPrintedString( it, s, t )
}


String toPrintedString(Object[] args) {
    args
    .inject(''<<'') {
        acc, val ->  acc << val.toString().padRight(25)
    }
    .toString()
}