localStorageでブラウザの状態を同期するやつ

state.coffee

# localStorageで状態を保存・同期するやつ
#
# example:
#   State.set('key', 'value')
#   State.on('key', (changedValue) ->
#     update(changedValue)
#   )
angular.module('state')
  .service 'State', [
    'localStorageService'
    '$interval'
    (localStorageService, $interval) ->
      Storage = localStorageService

      class State extends EventEmitter2
        constructor: ->
          EventEmitter2.call(this)

          @_watchStorage()

          this

        set: Storage.set.bind(Storage)
        get: Storage.get.bind(Storage)

        # @private
        # pollingしてlocalStorageの値に変更があるか見る
        _watchStorage: ->
          @_takeSnapshot()

          $interval(=>
            Storage.keys().forEach((key) =>
              currentValue = Storage.get(key)
              unless currentValue == @snapshot[key]
                @emit(key, currentValue)
            )
            @_takeSnapshot()
          , 100)

        _takeSnapshot: ->
          @snapshot = @_fetchSnapshot()

        _fetchSnapshot: ->
          data = {}
          Storage.keys().forEach((key) ->
            data[key] = Storage.get(key)
          )
          data

      new State()
  ]