ttfautohint-nodocs

PKGBUILD

# Maintainer: Pau Ruiz Safont <unduthegun at gmail dot com>
# Contributors: Mario Finelli <mario at finel dot li>
#               Arthur Titeica <arthur dot titeica at gmail dot com>
# Removed dependencies for building docs as it's broken with pandoc >= 2.0

_basename=ttfautohint
pkgname=$_basename-nodocs
pkgver=1.8.3
pkgrel=0
pkgdesc="Provides automated hinting process for web fonts, without docs so it's buildable"
arch=('i686' 'x86_64')
url="http://www.freetype.org/ttfautohint/"
license=('GPL' 'custom')
depends=('freetype2' 'qt5-base')
provides=($_basename)
conflicts=($_basename)
source=(https://download.savannah.gnu.org/releases/freetype/${_basename}-$pkgver.tar.gz{,.sig})
sha256sums=('87bb4932571ad57536a7cc20b31fd15bc68cb5429977eb43d903fa61617cf87e'
            'SKIP')
validpgpkeys=('58E0C111E39F5408C5D3EC76C1A60EACE707FDA5')

build() {
  cd "$srcdir/${_basename}-$pkgver"
  export QMAKE='/usr/bin/qmake'
  export MOC='/usr/bin/moc'
  export UIC='/usr/bin/uic'
  export RCC='/usr/bin/rcc'
  ./configure --prefix=/usr --with-qt=/usr/lib/qt --without-doc \
    --with-freetype-config="pkg-config freetype2"
  make
}

check() {
  cd "${srcdir}/${_basename}-${pkgver}"
  make -k check
}

package() {
  cd "${srcdir}/${_basename}-${pkgver}"
  make DESTDIR="${pkgdir}/" install

  install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${_basename}/COPYING"
  install -Dm644 FTL.TXT "${pkgdir}/usr/share/licenses/${_basename}/FTL.TXT"
}