ocaml-calendar updated PKGBUILD

PKGBUILD

# Maintainer: oliver < a t >  first . in-berlin . de
# Contributor: Serge Zirukin <[email protected]>
# Contributor: Sergei Lebedev <[email protected]>
# Contributor: Kostas Andreadis <[email protected]>
# Contributor: Thomas S Hatch <thatch45 at gmail dot com>
# Contributor: Gerad Munsch <[email protected]>
pkgname=ocaml-calendar
pkgver=2.03.2
pkgrel=4
pkgdesc="OCaml library managing dates and times"
arch=('i686' 'x86_64')
url="http://calendar.forge.ocamlcore.org"
license=('LGPL')
depends=('ocaml')
makedepends=('ocaml-findlib')
source=(http://forge.ocamlcore.org/frs/download.php/915/calendar-$pkgver.tar.gz)
md5sums=('4f50e3c9ad0eec3d06c0457a2ba0f0b4')
options=('!strip')

#OCAMLFIND_DESTDIR=$pkgdir$(ocamlfind printconf destdir)

build() {
  cd "$srcdir/calendar-$pkgver"
  ./configure --prefix=/usr
  make all doc
}

package() {
  cd "$srcdir/calendar-$pkgver"
  mkdir -p "${pkgdir}$(ocamlfind printconf destdir)"
  make OCAMLFIND_DESTDIR="${pkgdir}$(ocamlfind printconf destdir)" install
  install -d -m 0755 "${pkgdir}/usr/share/doc/$pkgname"
  install -t "${pkgdir}/usr/share/doc/$pkgname/" doc/*
  install -Dm 644 COPYING $pkgdir/usr/share/licenses/$pkgname/COPYING
}