Versioned struct generation in Zig

out.txt

$ zig test versioned_structs.zig                                                                                       ^0^ 17:58

v1:
field 0 is data_len type is i32
field 1 is data_ptr type is *const u8

example value: ver.MakeStruct(.{ .{ ... }, .{ ... }, .{ ... } },1){ .data_len = 420, .data_ptr = u8@deadbeef }

v69:
field 0 is data_len type is i32
field 1 is flag_owo type is u1
field 2 is data_ptr type is *const u8

example value: ver.MakeStruct(.{ .{ ... }, .{ ... }, .{ ... } },69){ .data_len = 420, .flag_owo = 1, .data_ptr = u8@badf00d }
All 1 tests passed.

versioned_structs.zig

// example for lina :3
// thx: https://mht.wtf/post/comptime-struct/
// zig version used: 0.14 dev
const std = @import("std");

fn MakeStruct(comptime in: anytype, version: comptime_int) type {
    var fields: [in.len]std.builtin.Type.StructField = undefined;
    var j = 0;
    for (in) |field_data| {
        if (@hasField(@TypeOf(field_data), "since") and field_data.since > version) continue;
        const fieldType: type = field_data.type;
        const fieldName: [:0]const u8 = field_data.name[0..];
        fields[j] = .{
            .name = fieldName,
            .type = fieldType,
            .default_value = null,
            .is_comptime = false,
            .alignment = 0,
        };
        j += 1;
    }
    return @Type(.{
        .@"struct" = .{
            .layout = .@"packed",
            .fields = fields[0..j],
            .decls = &[_]std.builtin.Type.Declaration{},
            .is_tuple = false,
        },
    });
}

test "make-struct" {
    const CommandSubmission = .{
        .{ .name = "data_len", .type = i32 },
        .{ .name = "flag_owo", .type = u1, .since = 69 },
        .{ .name = "data_ptr", .type = *const u8 },
    };

    const CommandSubmissionV1 = MakeStruct(CommandSubmission, 1);
    std.debug.print("\nv1:\n", .{});
    inline for (@typeInfo(CommandSubmissionV1).@"struct".fields, 0..) |f, i| {
        std.debug.print("field {} is {s} type is {s}\n", .{ i, f.name, @typeName(f.type) });
    }
    std.debug.print("\nexample value: {}\n", .{CommandSubmissionV1{ .data_len = 420, .data_ptr = @ptrFromInt(0xdeadbeef) }});

    const CommandSubmissionV69 = MakeStruct(CommandSubmission, 69);
    std.debug.print("\nv69:\n", .{});
    inline for (@typeInfo(CommandSubmissionV69).@"struct".fields, 0..) |f, i| {
        std.debug.print("field {} is {s} type is {s}\n", .{ i, f.name, @typeName(f.type) });
    }
    std.debug.print("\nexample value: {}\n", .{CommandSubmissionV69{ .data_len = 420, .data_ptr = @ptrFromInt(0xbadf00d), .flag_owo = 1 }});
}