litecoin-qt PKGBUILD for 0.6.9.2

PKGBUILD

# Maintainer: Loïc Guitaut <flink at belfalas dot eu>
# Contributor: Noel Maersk <veox at wemakethings dot net>

pkgname='litecoin-qt'
pkgver=0.6.9.2
pkgrel=1
arch=('i686' 'x86_64')
url="http://www.litecoin.org/"
makedepends=('boost' 'automoc4' 'qrencode' 'miniupnpc')
license=('MIT')
pkgdesc="Peer-to-peer network based digital currency (QT)"
depends=(boost-libs qt4 miniupnpc qrencode)
conflicts=(litecoin)
install=litecoin-qt.install
source=("http://litecoin.org/downloads/linux/litecoin-0.6.9.2-linux.tar.xz"
        "$pkgname.desktop")
sha256sums=('1f75361a1a69bb222d9a7aebfd2d1bf8bed21fb1627424bfcc5110676a096db5'
            '65fd2e3bbefdb77d955446cc94b54d5f79644dea93d4c9a1425ea01ee14c902a')

build() {
  cd "$srcdir/litecoin-$pkgver-linux/src"

  # and make qt gui
  qmake-qt4 USE_QRCODE=1 USE_UPNP=1
  make
}


package() {
  install -Dm644 litecoin-qt.desktop "$pkgdir"/usr/share/applications/litecoin.desktop
  cd "$srcdir/litecoin-$pkgver-linux/src"
  install -Dm755 litecoin-qt "$pkgdir"/usr/bin/litecoin-qt
  install -Dm644 share/pixmaps/bitcoin80.xpm "$pkgdir"/usr/share/pixmaps/litecoin80.xpm

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}