namecoin-daemon-git PKGBUILD for Arch Linux AUR

PKGBUILD

# Maintainer: huma
# Contributor: Noel Maersk <veox at wemakethings dot net>

pkgname=namecoin-daemon-git
_gitname=namecoin
pkgver=20131031
pkgrel=1
pkgdesc="Headless namecoin daemon (git version)"
arch=('i686' 'x86_64')
license=('MIT')
url="https://github.com/namecoin/namecoin"
makedepends=('boost>=1.40' 'miniupnpc' 'git')
provides=('namecoin-daemon')
conflicts=('namecoind')
source="git://github.com/namecoin/namecoin.git"
md5sums=('SKIP')

pkgver() {
  cd "$srcdir/$_gitname"

  # Use the tag of the last commit
  #git describe --always | sed 's|-|.|g'

  # Use date
  git log -n1 --format="%ci" | awk '{print $1}' | sed s/-//g
}

build() {
  cd "$srcdir/$_gitname/src"

  sed -i '15s|Bstatic|Bdynamic|' makefile.unix # boost fix
  make -f makefile.unix namecoind
}

package() {
  cd "$srcdir/$_gitname/src"

  install -Dm0755 namecoind ${pkgdir}/usr/bin/namecoind
  install -Dm644 ../COPYING ${pkgdir}/usr/share/licenses/${pkgname}/COPYING
}