End-of-the-day automation

endoftheday.scpt

on run {}
	-- reset file
	do shell script "/usr/bin/git -C ~/path/to/repo checkout -- path/to/file/in/repo.txt"

	tell application "Finder"
		close every window
		set trashcount to count of items of the trash
		if trashcount > 0 then
			empty the trash
		end if
	end tell
	try
		tell application "Calendar" to if it is running then quit
	end try
	
	-- get list of open apps
	tell application "System Events"
		set allFrontApps to displayed name of (every process whose background only is false) as list
	end tell
	
	-- leave some apps open 
	set exclusions to {"Calendar", "Finder", "LaunchBar"}
	
	-- leave even windows open of some apps
	set exclusionsToHide to {"LaunchBar", "Finder", "System Information"}
	
	-- quit each app or just hide
	repeat with thisApp in allFrontApps
		set thisApp to thisApp as text
		if thisApp is not in exclusions then
			tell application thisApp to quit
		else
			if thisApp is not in exclusionsToHide then
				tell application "System Events"
					set visible of application process thisApp to false
				end tell
			end if
		end if
	end repeat
end run