Medley of Danger - a stub shooter interactive finction (aka text adventure) game.

Medley of Danger.inform

[Please remember that, in order to compile, you'll most likely need the sounds and cover art. Do not redistribute pre-final compiled versions of the game without the author (Gustavo6046)'s permission!]
"Medley of Danger" by Gustavo Ramos Rehermann

Use American dialect. Use scoring.
Release along with cover art ("Medley of Danger").

Part 1 - Vibes of War

Section 1 - Basics of the world

The carrying capacity of the player is 4.
[Player's holdalls can have a number called carrying capacity.]
[In the the Craftsman's Hole is a leather bag. A leather bag is a player's holdall. The leather bag's carrying capacity is 5.]

Everything can be new or old.
A medikit is a kind of thing.
Every medikit has a number called heal.
A room marker is a kind of thing.
Every animal can be male or female. Every animal has a number called strength.
Definition: a person is male if they are a male animal or they are a man.
Definition: a person is female if they are a female animal or they are a woman.
A vest is a kind of thing. A vest is usually wearable.
Every vest has a text called color.
An armor is a kind of vest.
A snake is a kind of animal.
The strength of an animal is usually 18. The strength of a snake is usually 40.
Every armor has a number called absorption factor.
The absorption factor of an armor is usually 1300.
The color of a vest is usually "blank".
A shirt is a kind of vest.
Room markers can be uninitialized or initialized.
Room markers are usually scenery and fixed in place.
A clip of ammunition is a kind of thing. The plural of clip of ammunition is clips of ammunition.
Every clip of ammunition has a number called caliber.
Every clip of ammunition has a number called content.
The Bunker is a room. "'This old concrete bunker must have been around for quite a long time', you think to yourself, as you examinate the multiple cracks in the inner wall."
The Underground is a region.
The Bunker is a room. The Secret Room is a room. The Secret Room is in the Underground. A man called Mahjong is in the Secret Room. "Some dude, wearing a shirt of a wine-ish tone of red, seems, at first glance, to dwell this place. It is unknown how he hid in such a secret room. He calls himself Mahjong..." Mahjong wears a shirt called Mahjong's shirt. The color of the shirt is "wine". 
A corridor is a kind of room.
Objects can be easy to destroy, hard to destroy or indestructible.
The bunker is indestructible.
Vests can be headwear, bodywear, legwear, handwear or footwear.
A vest is usually bodywear.

Section 2 - Food and Weaponry

A weapon is a kind of thing. ["Anything with which a person can damage another object."]
A weapon can be melee or ranged.
A gun is a kind of weapon. ["Any ranged firearm weapon is a 'gun'."]
[You have a gun called wielded weapon.]
Every gun has a number called bullet caliber.
A gun is ranged.
A gun has a number called firepower.
A gun has a number called ammo.
An object has a number called health.
The health of people is usually 75.
People can be friendly or enemy.
A snake is usually enemy.
People can be dead or alive.
People are usually alive.
The heal of medikits is usually 30.
The health of Yourself is 100.

To debug-say (t - text):
	let debug be false;
	if debug is true:
		say t.

Things can be combat-active or combat-inactive.
Targetless is a privately-named scenery thing.

To shoot-verify (target - a thing) by (shooter - a thing) and (print - truth state) print:
	if the health of the target is at most 0:
		now the shooter is combat-inactive;
		now the target of the shooter is targetless;
		if the location of target is the location of Yourself or the location of target is the location of You:		
			if the target is yourself or the target is You:
				if print is true, say "[You] die!";
			otherwise if the target is a person:
				if print is true, say "[The target] dies!";
			otherwise if target is not a person:
				if print is true, say "[The target] is destroyed!";
			if the target is you or the target is yourself:
				if yourself are cheating:
					say "Your humiliatingly high powers revive you as an humiliatingly ugly person full of bullet holes and blast marks!";
					now the health of yourself is 100;
					stop;
				otherwise:
					end the story finally;
		repeat with inv running through every thing carried by target:
			if inv is a medikit:
				if print is true, say "[the target] drops [inv], which is then taken and used by the ingenuous shooter.";
				increase the health of the shooter by the heal of inv;
				if the health of the shooter is greater than 100:
					now the health of the shooter is 100;
				now inv is nowhere;
			otherwise:
				now shooter carries inv;
		now the target is dead;
		if the shooter is you:
			if the target is friendly:
				decrease score by 10;
			otherwise:
				increase score by 35;
			now the target is killed by the player;
	otherwise:
		now the shooter is combat-active;
		now the target of the shooter is the target;
		if the target is you or the target is yourself:
			if print is true, say "[You] take [first time]very burdening [only]damage[first time], like you never felt before[only]!";
		otherwise:
			if the target is friendly and (the shooter is you or the shooter is yourself):
				let dictator be "[one of]Hitler[or]Stalin[or]Hirohito[or]Mussolini[or]Benito[or]Soviet Union[or]the lurking grue[purely at random]";
				let possib 1 be "for such a [one of]horrible[or]inhuman[or]calunious[or]insulting[or]defective[purely at random] [one of]activity[or]act[or]issue[or]trouble[or]sin[or]crap you took in [the target]'s head[as decreasingly likely outcomes]";
				let possib 2 be "now that you [one of]showed your dark, evil side[or]drew a swastika on the wall of your classroom[or]were caught praising [dictator][purely at random].";
				let possib 3 be "after that [one of]activity[or]act[or]issue[or]trouble[or]sin[or]crap you took in [the target]'s head[as decreasingly likely outcomes]";
				say "[The target] is going to retaliate [one of][possib 1][or]after what you did to them[or][possib 2][or][possib 3][as decreasingly likely outcomes].";
				now the target is an enemy.

Before printing the name of the gun: say "the ".
Before printing the name of a vest: say "the [color] ".
Before printing the name of a person: say "[if dead]the corpse of ".
Before printing the name of a clip of ammunition: say "the ".

Sound of gunfire is the file "Gunfire.ogg".

To shoot (target - an object) with (gun - a gun) by (shooter - an object):
	play the sound of gunfire;
	if the holder of the gun is not the shooter and (the shooter is not You or the holder of the gun is not Yourself):
		if the shooter is you:
			say "[The shooter] don't carry [the gun]; ";
		otherwise:
			say "[The shooter] doesn't carry [the gun]; ";
		if the holder of the gun is nothing:
			if the location of the gun is the location of the shooter:
				say "it is on the floor!";
			else:
				say "it is elsewhere!";
		else:
			say "it pertains to [holder of the gun]!";
	otherwise if the health of the target is less than 1 and the shooter is yourself:
		say "The target is already eliminated!";
		if the target is not yourself:
			now the target is nowhere;
	otherwise if the ammo of gun is greater than 0:
		if the shooter is you:
			if the target is you:
				say "You aim [the gun] towards yourself, and POW! [one of]Your desistive feelings transmutate into lead and blood, in a very short span of time, but for a long duration.[or]Death further approaches.[stopping]";
			otherwise:
				say "You aim [the gun] towards [the target], and POW! [the target] took pelt from your [gun]!";
		otherwise if the target is you or the target is yourself:
			say "[the shooter] aims [the gun] towards you, and POW! You ate [one of]lead[or]plumbum[or]fire[or]deadly pellets[or]fire[or]sorrow[purely at random] from their [gun]! [first time]It hurts intensely! You can't imagine yourself getting used to it.[only]";
		otherwise:
			if the location of the shooter is the location of yourself:
				if the location of the target is the location of yourself:
					say "[The shooter] aims [the gun] towards [the target], and POW! [The shooter] shot [the target] with their [gun]!";
				otherwise:
					say "[The shooter] aims [the gun] towards something, and POW! [The shooter] shot it with their [gun]!";
			otherwise:
				if the location of the target is the location of yourself:
					say "Someone aims [the gun] towards [the target], and POW! [The shooter] shot [the target] with their [gun]!";
		decrement the ammo of the gun;
		[say "[the health of the target] - [firepower of the gun] = [the health of the target - firepower of the gun].";]
		let fp be 1000 * the firepower of the gun;
		decrease the health of the target by (fp / (1000 + total absorption factor of armors worn by the target));
		if the target is you or the target is yourself:
			shoot-verify yourself by the shooter and true print;
		else:
			if the location of the target is the location of Yourself:
				shoot-verify the target by the shooter and true print;
			otherwise:
				shoot-verify the target by the shooter and false print;
	otherwise:
		if the shooter is You:
			say "[The shooter] aim [the gun] towards [the target], and... *Clic*! You shudder in fear, as you realize you hadn't gotten ammunition - the enemies might strike at any time!";
		otherwise if the shooter is a person:
			if the shooter is English:
				say "[The shooter] aims [the gun] towards [the target], and... *Clic*! The sound emanates, reliefing [target]. 'Damn this crap, I have to find ammo for it all the time!', slangly exclaims [the shooter]' in a yelling bout of frustration and fear.";
			otherwise if the shooter is German:
				say "[The shooter] aims [the gun] towards [the target], and... *Clic*! The sound emanates, reliefing [target]. 'Leere Munitionskartuchen! Gah!', cryptically exclaims [the shooter]' in a yelling bout of frustration and fear.";
			otherwise if the shooter is Japanese:
				say "[The shooter] aims [the gun] towards [the target], and... *Clic*! The sound emanates, reliefing [target]. 'Motto dan'yaku o motte ki nasai!', cryptically orders [the shooter]', hoping to be heard by Japanese comrades, in a yelling bout of frustration and fear.";
		otherwise:
			say "*[The shooter] aims [the gun] towards [the target], and... Clic*! The sound barely damages [the target]. [The shooter] flinches in response.".

To reload (gun - a gun) with (ammo - an clip of ammunition):
	if the bullet caliber of the gun is not the caliber of the ammo:
		say "The calibers don't match! [if the bullet caliber of the gun is less than the caliber of the ammo]The clip doesn't fit! It's too wide![otherwise]The clip isn't wide enough to clamp to the gun.[end if]";
	else:
		if the content of the ammo is greater than the ammo of the gun:
			say "The gun is reloaded; now it has some more rounds.";
		otherwise if the content of the ammo is greater than 0:
			say "The gun is reloaded; now it has some rounds, but a quick shake check for ammunition doesn't sound promising in terms of effectiveness.";
		otherwise:
			say "The gun is apparently reloaded, but it doesn't sound like it has any round loaded! You need another clip! Curse and swear!";
		now the ammo of the gun is the content of the ammo;
		now the ammo is nowhere.

Shooting is an action applying to two things.
Shooting with is an action applying to two things.
Reloading it with is an action applying to two things.

Before taking a medikit:
	say "You use the medikit, which heals you[if the heal of the noun is less than 11 or the health of Yourself is greater than 89] a bit[end if]. [if the health of Yourself is less than 30]You feel much better!";
	increase the health of Yourself by the heal of the noun;
	if the health of Yourself is greater than 100:
		now the health of Yourself is 100;
	now the noun is nowhere.

Carry out reloading it with:
	if the noun is not a gun:
		say "You can't reload something that isn't a gun ([the noun])!";
	otherwise if the second noun is not an clip of ammunition:
		say "You can't reload with something that isn't ammo ([the second noun])!";
	otherwise if the noun is not carried by yourself:
		say "You don't carry [the noun]!";
	otherwise if the second noun is not carried by yourself:
		say "You don't carry [the second noun]!";
	otherwise:
		reload the noun with the second noun.

[Carry out wielding:
	silently try taking the noun;
	now the wielded weapon of you is the noun;
	say "You now have [a noun] in your hands."
	
Instead of wielding something that is not a weapon:
	say "But sir, how do you expect to use [the noun] as a weapon?!".]

Carry out shooting:
	if the second noun is not a gun:
		say "You aim your... wait... wield a gun, not [a second noun], please!";
	otherwise:
		shoot the noun with the second noun by You.

Carry out shooting with:
	if the noun is not a gun:
		say "You aim your... wait... wield a gun, not [a noun], please!";
	otherwise:
		shoot the second noun with the noun by You.

Dying is an action applying to nothing.
Before dying:
	say "Are you sure? If you can't control such a dramatic and emotional surge, please use the 'superdie' verb."

To destroy (obj - an object):
	if obj is an indestructible object, stop the action; say "[The obj] is indestructible!";
	if obj is a hard to destroy object, say "[The obj] is barely destructible."; continue the action;
	if obj is an easy to destroy object, continue the action.

Superdying is an action applying to nothing.
Before superdying:
	end the story	saying "You ingest the cyanide pill you were given in case you were interrogated. It is effective... in an obituary way..."
	
Understand "die" as dying.
Understand "superdie" as superdying.

A food is a kind of thing.
The health of a food is 5.
A food can be healthy, neutral or unhealthy. A food can be tasteful, too bitter, too sweet or horrible.
A person has a number called hunger.You have a number called hunger.
Every person can be well or ill.
People are usually well.
A food has a number called calories.
People can be killed by the player or not killed by the player. People are usually not killed by the player.

A food called red apple is in Storage Room. The calories of red apple is 5. The apple is healthy. The apple is tasteful.
A food called war ration is in Storage Room. The calories of war ration is 12. The war ration is too bitter.
A food called soup is in Storage Room. The calories of soup is 9. The soup is tasteful.
A food called truffle is in the Bunker. The calories of truffle is 4. The truffle is unhealthy. The truffle is too sweet.

Status-printing is an action applying to nothing.

Carry out status-printing:
	say "You are [if yourself is well]healthy[otherwise]ill[end if].";
	say "You are [if hunger of yourself is greater than 50]starving[otherwise if hunger of yourself is greater than 38]very hungry[otherwise if hunger of yourself is greater than 13]hungry[otherwise]not hungry at all[end if].";
	say "You have [the number of entries in the list of every gun carried by yourself in words] guns.";
	say "You own in total [total ammo of every gun carried by yourself in words] rounds.";
	say "You have killed [the number of entries in the list of every killed by the player person in words] people, of which [the number of entries in the list of every killed by the player animal in words] were animals."

To check decreased hunger:
	if hunger of yourself is greater than 50:
		say "You can still hear the stream of the sand falling on the base of Death's hourglass. He waits...";
	otherwise if hunger of yourself is greater than 38:
		say "You still feel nutritionally fragile.";
	otherwise if hunger of yourself is greater than 13:
		say "You still feel hungry.";
	otherwise:
		say "You don't feel hungry at all anymore!".

To check hunger:
	if hunger of yourself is 13, say "You begin to feel hungry.";
	if hunger of yourself is 38, say "You feel nutritionally fragile.";
	if hunger of yourself is 50, say "You almost can sense Death, waiting for starvation to consume your last senses, while he readies his scythe, your vehicle to Heaven — or Hell, who knows...";
	if hunger of yourself is greater than 54:
		say "You starve... all your thoughts and emotions fade into smithereens, in space and time...";
		end the story finally.

Every turn:
	increment the hunger of yourself;
	check hunger;
	if yourself are ill:
		increment the hunger of yourself;
		check hunger.

Every turn:
	repeat with enm running through every person:
		if enm is an enemy and enm is alive and enm is not an animal and enm carries a gun and enm is not yourself:
			let shot be false;
			repeat with fn running through every alive person:
				if fn is animal or fn is friendly:
					if the target of enm is targetless or the target of enm is fn:
						if fn is alive and fn is not you and fn is not yourself and the location of fn is the location of enm:
							debug-say "[the enm] threatens [the fn]!";
							repeat with wn running through every gun carried by enm:
								shoot fn with wn by enm;
								now shot is true;
								break;
							if shot is true:
								break;
			if shot is false:
				if the location of Yourself is the location of enm:
					if the target of enm is targetless or the target of enm is Yourself:
						debug-say "[the enm] threatens you!";
						repeat with wn running through every gun carried by enm:
							shoot yourself with wn by enm;
							now shot is true;
							break;
						if shot is true:
							next;	
	repeat with enm running through every person:
		if enm is friendly and enm is alive and the target of enm is targetless and enm is not an animal and enm carries a gun and enm is not you:
			let shot be false;
			repeat with fn running through every alive person:
				if fn is animal or fn is enemy:
					if the target of enm is targetless or the target of enm is fn:
						if fn is alive and the location of fn is the location of enm and fn is not you and fn is not yourself:			
							debug-say "[the enm] threatens [the fn]!";
							repeat with wn running through every gun carried by enm:
								shoot fn with wn by enm;
								now shot is true;
								break;
							if shot is true:
								break;

Every turn:
	repeat with p running through every person who is not yourself:
		if p is alive and p is not animal:
			repeat with w running through every gun:
				if the location of w is the location of p:
					if someone carries w:
						next;
					now p carries w;
					break;
			repeat with w running through every armor:
				if the location of w is the location of p:
					if someone carries w:
						next;
					now p carries w;
					break;
			repeat with w running through every food:
				if the location of w is the location of p:
					if someone carries w:
						next;
					now p carries w;
					break.

Usually people are combat-inactive.
Every thing has a thing called target.
The target of people is usually targetless.

Every turn:
	repeat with p running through every person who is not yourself:
		if p is combat-active and a random chance of 3 in 5 succeeds and the location of p is not the location of the target of p:
			let rt be the best route from the location of p to the location of the target of p;
			[say "[rt] [the room rt from the location of p].";]
			if rt is a direction and the room rt from the location of p is not nothing:
				move p to the room rt from the location of p;
				if the target of p is yourself and the location of p is the location of yourself:
					say "[the p] fiendishly tracked you down to here!";
	repeat with p running through every person who is not yourself:
		if p is not nothing and p is alive and p is combat-inactive and a random chance of 1 in 4 succeeds:
			let rm be a random initialized room marker;
			if rm is not nothing:
				if the location of rm is adjacent to the location of p:
					if the location of p is the location of yourself:
						say "[the p] wanders away, towards the [the location of rm] way.";
					move p to rm;
					if the location of p is the location of yourself:
						let gramo be "[one of]gramophone[or]phonograph[purely at random]";
						let language be "[if p is German]German[otherwise if p is Japanese]Japanese[otherwise if p is English]English[otherwise]silly hieroglyphs[end if]";
						let shout be "[if p is English]Halt now, and surrender; thou have now a very short life expectancy![otherwise if p is German]Nieder! Ich werde mit dir gerne umgehen, wenn du nicht gehorchst![otherwise if p is Japanese]Anata ga watashitachi ni tsuite nanika dekiru yo ni naru mae ni, watashi wa anata o owara semasu![end if]";
						let gpronoun be "[if p is a man]he[otherwise if p is a woman]she[otherwise]he[end if]";
						say "[the p] enters the room[if p is enemy][one of], reconizing your Allied uniform, and hoists![or] readying their weapon, just to find a target — you![or], distracted by the soothing sound of a [gramo]... only to stumble at your feet![or]; while reloading, [gpronoun] shouts at you with hostile words: '[shout]'[purely at random][otherwise]. They salute you in [language].[end if]".

Every turn:
	repeat with hazard running through every alive enemy animal:
		repeat with target running through every alive person:
			if location of target is location of hazard:
				decrease health of target by strength of hazard;
				if the target is yourself:
					say "[The hazard] attacks you!";
				otherwise if the location of the target is the location of yourself:
					say "[The hazard] attacks [the target]!";
				if the target is yourself:
					shoot-verify target by hazard and true print;
				otherwise:
					shoot-verify target by hazard and false print.

Manducating is an action applying to a thing.

Before manducating something that is a food:
	decrease hunger of yourself by calories of the noun;
	now the noun is nowhere;
	if the noun is tasteful:
		say "It tastes good enough to silence your hunger for a good time.";
		increase score by 20;
		check decreased hunger;
	if the noun is too bitter:
		say "It tastes too bitter to silence your hunger for long, but does an acceptable job, for a shorter and maybe reliefed time span.";
		increase score by 15;
		check decreased hunger;
	if the noun is too sweet:
		say "It tastes too sweet to quiet your hunger, and gives you a short stomach ache; but manages to control your desire of eating.";
		increase score by 10;
		check decreased hunger;
	if the noun is horrible:
		say "It doesn't taste anything; it is horrible! You quickly spit the food, but by then the bad taste has already corrupted your tongue.";
		decrease score by 5;
		check decreased hunger;
	if yourself is well and the noun is unhealthy:
		now yourself is not well;
		decrease score by 8;
		say "You feel like your stomach wants to turn inside out, and your lungs want to burst out of your chest.";
	if yourself is ill and the noun is healthy:
		now yourself is well;
		increase score by 12;
		say "All these near inane feelings of hopelessness and sorrow are suddenly gone; you are now feeling better!";
	rule succeeds.

Before manducating something that is not a food:
	say "I don't want to challenge you, but that seems unhealthier than inedible. If your only purpose for that is to eat it, please throw it away!";
	rule fails.

Instead of tasting something that is not a food:
	say "You recognize the bad idea of your desires, and spit all the inedible content away."
	
Instead of tasting something that is a food:
	if the noun is tasteful:
		say "It seems to taste good enough. You get eager.";
	if the noun is too bitter:
		say "It tastes too bitter. You feel your tongue sorrowing...";
	if the noun is too sweet:
		say "It tastes too sweet; a dose of sacarose.";
	if the noun is horrible:
		say "It doesn't taste anything; it is horrible! You quickly spit the food.";
	if the noun is unhealthy:
		say "Something in this food seems to try to warn of consequences";
		if a random chance of 1 in 15 succeeds, say "You shrug back to that something. Awkward, isn't it?".

Section 3 - Shaping the world

Chapter 1 - Fearsome Crescendo

Everyone can be English, German or Japanese.
The Storage Room is a room. The Storage Room is in the Underground. The Secret Access Room is a room. The Secret Access Room is in the Underground. The Secret Room is north of the Dark Sinister Tunnel. The Stairwell is a room. The Stairwell is in the Underground. The Storage Room is west from the Stairwell. The Stairwell is south of the Stair Corridor. The Stair Corridor is in the Underground. The Stair Corridor is northeast of the Storage Room. [The Secret Access Room is south from The Craftsman's Hole.] The Craftsman's Hole is a room. The Craftsman's Hole is in the Underground. The Stairwell is below the Bunker. The stairway is a backdrop in The Stairwell. The Dark Sinister Tunnel is a corridor. "The war has destroyed the Dark Sinister Tunnel, making it a barely accessible hole utterly filled with debris and large rocks." The Dark Sinister Tunnel is northwest of the Secret Access Room. The Dark Sinister Tunnel is in the Underground. The Craftsman's Hole is northwest from the Stair Corridor. The Craftsman's Hole is west from the Secret Access Room. The description of the Stairway is "The only way to get to the bunker, folks!".

To decide which number is the room item count (r - room) (this is item counting):
	let result be 0;
	increase result by the number of foods in r;
	increase result by the number of guns in r;
	increase result by the number of clips of ammunition in r;
	increase result by the number of player's holdalls in r;
	decide on result.

The description of the Storage Room is "A small place, [if item counting applied to Storage Room is greater than 0]further clogged by every kind of item[otherwise]almost unclogged, thanks to your hands that like to TAKE EVERYTHING (shouldn't that be a cheat, anyway?)[end if].[first time] East to the Stairwell; northeast to the Stair Corridor.[only]".
The description of the Stairwell is "A moderately-heighted vertical shaft, in the middle of the which is a stairway.[first time] West to the Storage Room; north to the Stair Corridor.[only]".
The description of the Stair Corridor is "A corridor, with smoothened stone extending into a not-so-long distance in the walls.[one of] This seems a bit creepy... You will likely get used to it! Northwest to the Craftsman's Hole, southwest to the Storage Room, and south to the Stairwell.[or] Your shivers aren't so intense anymore...[or] You get used to this corridor! Now you know it like the names of the fingers of your hand.[or][stopping]".
The description of the Craftsman's Hole is "A place that has some woodcraft equipment; you wonder what German, Japanese, or God-knows-where-from used to make chairs here![first time] Southeast to the Stair Corridor.[only]".
In the Craftsman's Hole is a supporter called cutting table. The description of the cutting table is "This table seems like it was used to cut wood into pieces." On the cutting table is a gun called wooden pistol. On the cutting table is a clip of ammunition called wooden clip. The description of the wodden pistol is "A wooden pistol, that seems to deal small damage. It has a large magazine, though!" The caliber of the wooden clip is 10. The bullet caliber of the wooden pistol is 10. The ammo of the wooden pistol is 7. The firepower of the wooden pistol is 21. The content of the wooden clip is 28. The description of the wooden clip is "Wooden clips, that contain presumably lots of these small-caliber wooden rounds. Would that be for the wooden pistol?".

In the storage room is a player's holdall called leather bag. The description of the leather bag is "This bag will help you carry most things in general."
In the storage room is a gun called pistol. The description of the pistol is "This pistol is going to be the secret for your survival around these hostile places." The firepower of the pistol is 27. The ammo of the pistol is 16. The bullet caliber of the pistol is 12. 
In the Secret Room is a gun called bazooka. The description of the bazooka is "Ooh, firepower! Explosions! Exactly what was missing when you studied Chemistry back in the day. Oh, damn formula balancement; I want my sodium + water = BLAST!" The firepower of the bazooka is 500. The ammo of the bazooka is 5. The bullet caliber of the bazooka is 520.
In the Stair Corridor is a medikit. The description of the medikit is "A medikit will save you when you need it the most; but you can't carry it, since taking it will heal you instead." The heal of the medikit is 45.
In the Stair Corridor is a man called Dankhmann. He is an enemy. The description of the Luger is "The Parabellum-Pistole (known in the US as Luger) - a semiautomatic German pistol designed in 1898." A gun called Luger is carried by Dankhmann. The firepower of the Luger is 20. The ammo of the Luger is 5. The bullet caliber of the Luger is 12.
Dankhmann is German.
In the Dark Sinister Tunnel are two snakes. The strength of the snakes is 37.
In the Craftsman's Hole is a snake. The strength of the snake is 20.
In the Craftsman's Hole is a clip of ammunition called bullet clip. The description of the bullet clip is "A clip with which to reload pistols (including most Lugers) and machine guns." The caliber of the bullet clip is 12. The content of the bullet clip is 20.
In the Bunker is a clip of ammunition called clip. The caliber of the clip is 12. The content of the clip is 0.
In the Bunker is a man called Pakat. He is an enemy. Pakat is German. Pakat carries a gun called MP40. The bullet caliber of the MP40 is 12. The ammo of the MP40 is 11. The firepower of the MP40 is 31.
In the Bunker is a woman called Missumi. She is an enemy. Missumi is Japanese. Missumi carries a gun called Missumi's Luger. The bullet caliber of Missumi's Luger is 12. The ammo of Missumi's Luger is 2. The firepower of Missumi's Luger is 20. Missumi carries a medikit called iryō. The heal of the medikit is 40. The description of iryō is "A medikit will save you when you need it the most; but you can't carry it, since taking it will heal you instead."
In the Storage Room is a clip of ammunition called box of missiles. The caliber of the box of missiles is 520. The content of the box of missiles is 4.
In the Stairwell is a supporter called table. The description of the table is "This is a standard table of Brazilian legal wood. Below it is a drawer.". Part of the table is an openable container called drawer. The drawer is closed. The description of the drawer is "It's just a wooden drawer. [if the drawer contains anything]You feel like it has something, though.[otherwise]A plain boring one." A bodywear armor called bulletproof coat is inside the drawer. The color of the bulletproof coat is "greenish brown". The absorption factor of the bulletproof coat is 1350. The description of the coat is "This suit will help you deal with lead. But not with a lot of it."
The stone floor is a backdrop. The stone floor is in the Underground. The description of the stone floor is "[one of]An annoyingly sharp stone floor can be seen below your feet.[or]You begin to get annoyed with the rocks getting into your war shoes.[or]The same plain boring stone floor extends throughout the aforementioned walkable surface of these underground rooms.[or]A stone floor is below your feet.[stopping]".
In the Bunker are 100 uninitialized room markers.

Autodestroying is an action applying to nothing.
Cheat toggling is an action applying to nothing.
Sound of creepy organs announcing the fall of thunders is the file "Organlol.ogg".

People can be cheaty or fair.
People can be cheating or playing.

A person is usually fair and playing. 

Carry out cheat toggling:
	if yourself is not cheating:
		play the sound of creepy organs announcing the fall of thunders;
		say "Thunders fall and a scary sound plays, as you acticate the Stupidly Awkward Divine Ability Mode.";
		now yourself is cheating;
	otherwise:
		say "Thunders rise and a scary sound stops, as you deacticate the Stupidly Awkward Divine Ability Mode.";
		now yourself is not cheating;
		now yourself is not cheating.

Carry out autodestroying:
	if yourself is not cheating:
		say "Are you crazy?!";
	otherwise:
		say "Your eloquent craziness solidifies into the immediate presence of everyone formerly in the vicinity!";
		repeat with p running through every person:
			if p is not yourself:
				move p to Yourself.

Section 4 - Setting You up

Understand "eat [thing]" as manducating.
Understand "manducate [thing]" as manducating.
Understand "shoot [thing] with [weapon]" as shooting.
Understand "shoot at [thing] with [weapon]" as shooting.
Understand "shoot [weapon] at [thing] " as shooting with.
Understand "fire at [thing] with [weapon]" as shooting.
Understand "fire [weapon] at [thing]" as shooting with.
Understand "reload [weapon] with [thing]" as reloading it with.
Understand "fill [weapon] with [thing]" as reloading it with.
Understand "autodestroy" as autodestroying.
Understand "cheat mode" as cheat toggling.
Understand "status" as status-printing.
[Understand "wield [thing]" as wielding.]

health of yourself is 100.
Yourself is well. Mahjong is friendly.

When play begins:
	say "World War II has been generating death and building destruction all around the world, especially thorough on Europe. It is up to you whether to settle it or doom Humanity with it. You now are trapped in a bunker; you somehow sneaked in to steal weaponry, contradicting to your assignment: wiping the bunker's inhabitants with a flamethrower. Be wary!";
	Now Mahjong is friendly;
	Repeat with r running through every room:
		Let rm be a random uninitialized room marker;
		If rm is not nothing:
			Move rm to r;
			Now rm is initialized;
		Otherwise:
			say "Warning: no initial room markers found.";
			break;
	Repeat with rm running through every uninitialized room marker:
		Now rm is nowhere.
	
Yourself are in the Storage Room.

Every turn:
	say "Your health is [health of Yourself].".