more compile testing

typescript.txt

Script started on Mon Nov 10 08:00:40 2014
[warewolf@xanatos yubikey-personalization-gui-3.1.17]$ cat YKPersonalization.pro 
#
# global definitions
#
VERSION_MAJOR   = 3
VERSION_MINOR   = 1
VERSION_BUILD   = 17
VERSION         = "$${VERSION_MAJOR}.$${VERSION_MINOR}.$${VERSION_BUILD}"
APP_NAME        = $$quote(YubiKey Personalization Tool)

#
# common configuration
#
QT             += core gui
#QTPLUGIN       += qtaccessiblewidgets qmng
TEMPLATE        = app
TARGET          = yubikey-personalization-gui

DEFINES        += VERSION_MAJOR=\\\"$${VERSION_MAJOR}\\\" VERSION_MINOR=\\\"$${VERSION_MINOR}\\\" VERSION_BUILD=\\\"$${VERSION_BUILD}\\\" VERSION=\\\"$${VERSION}\\\"

CONFIG         += exceptions

# if this is qt5, add widgets
greaterThan(QT_MAJOR_VERSION, 4) {
    QT += widgets
    macx {
        QT += printsupport
        QTPLUGIN.platforms = qcocoa
    }
}

!nosilent {
    CONFIG         += silent
}

CONFIG(debug, debug|release) {
    message("Debug build")
    TARGET_DIR  = build$${DIR_SEPARATOR}debug

    QT += testlib

    CONFIG     += console no_lflags_merge
} else {
    message("Release build")
    TARGET_DIR  = build$${DIR_SEPARATOR}release

    DEFINES    += QT_NO_DEBUG_OUTPUT
}

UI_DIR          = ./src/ui
RCC_DIR         = "$$TARGET_DIR/RCCFiles"
MOC_DIR         = "$$TARGET_DIR/MOCFiles"
OBJECTS_DIR     = "$$TARGET_DIR/ObjFiles"
DESTDIR         = "$$TARGET_DIR"

DEPENDPATH     += . src src/ui
INCLUDEPATH    += . src src/ui

LICENSEFILES    = json-c.txt \
                  libyubikey.txt \
                  yubikey-personalization.txt

FORMS += \
    src/ui/toolpage.ui \
    src/ui/staticpage.ui \
    src/ui/settingpage.ui \
    src/ui/otppage.ui \
    src/ui/oathpage.ui \
    src/ui/mainwindow.ui \
    src/ui/helpbox.ui \
    src/ui/confirmbox.ui \
    src/ui/chalresppage.ui \
    src/ui/aboutpage.ui \
    src/ui/diagnostics.ui \
    src/ui/yubiaccbox.ui

HEADERS += \
    src/ui/toolpage.h \
    src/ui/staticpage.h \
    src/ui/settingpage.h \
    src/ui/scanedit.h \
    src/ui/otppage.h \
    src/ui/oathpage.h \
    src/ui/mainwindow.h \
    src/ui/helpbox.h \
    src/ui/confirmbox.h \
    src/ui/chalresppage.h \
    src/ui/aboutpage.h \
    src/ui/diagnostics.h \
    src/ui/yubiaccbox.h \
    src/yubikeywriter.h \
    src/yubikeyutil.h \
    src/yubikeylogger.h \
    src/yubikeyfinder.h \
    src/yubikeyconfig.h \
    src/version.h \
    src/otpdef.h \
    src/help.h \
    src/common.h

SOURCES += \
    src/main.cpp \
    src/ui/toolpage.cpp \
    src/ui/staticpage.cpp \
    src/ui/settingpage.cpp \
    src/ui/scanedit.cpp \
    src/ui/otppage.cpp \
    src/ui/oathpage.cpp \
    src/ui/mainwindow.cpp \
    src/ui/helpbox.cpp \
    src/ui/confirmbox.cpp \
    src/ui/chalresppage.cpp \
    src/ui/aboutpage.cpp \
    src/ui/yubiaccbox.cpp \
    src/ui/diagnostics.cpp \
    src/yubikeywriter.cpp \
    src/yubikeyutil.cpp \
    src/yubikeylogger.cpp \
    src/yubikeyfinder.cpp \
    src/yubikeyconfig.cpp

RESOURCES += \
    resources/resources.qrc

OTHER_FILES += \
    resources/win/resources.rc \
    resources/mac/Yubico.icns \
    resources/mac/Info.plist.in \
    resources/mac/qt.conf

cross {
    message("Doing a cross platform build..")
    QMAKE_CXXFLAGS += $$(CXXFLAGS)
    QMAKE_LFLAGS += $$(LDFLAGS)

    # pickup compiler from environment
    _TARGET_ARCH = $$(TARGET_ARCH)
    isEmpty(_TARGET_ARCH) {
        error("Cross compiling without a target is completely invalid, set TARGET_ARCH")
    }
    QMAKE_CC = $$(TARGET_ARCH)-gcc
    QMAKE_CXX = $$(TARGET_ARCH)-g++

    QMAKE_LINK = $$QMAKE_CXX
    QMAKE_LINK_C = $$QMAKE_CC

    win32 {
        QMAKE_LIB = $$(TARGET_ARCH)-ar -ru
        QMAKE_RC = $$(TARGET_ARCH)-windres $$quote(-DVERSION_WIN_STR=\'\\\"$${VERSION}\\0\\\"\')

        QMAKE_MOC = $$[QT_INSTALL_BINS]/moc
        QMAKE_UIC = $$[QT_INSTALL_BINS]/uic
        QMAKE_IDC = $$[QT_INSTALL_BINS]/idc
        QMAKE_RCC = $$[QT_INSTALL_BINS]/rcc

        QMAKE_LFLAGS += -static-libstdc++ -static-libgcc
    }

    _QTDIR = $$(QTDIR)
    !isEmpty (_QTDIR) {
      _QT_INCDIR = $$(QTDIR)$${DIR_SEPARATOR}include
      _QT_LIBDIR = $$(QTDIR)$${DIR_SEPARATOR}lib
      _QT_BINDIR = $$(QTDIR)$${DIR_SEPARATOR}bin
      _QT_PLUGINDIR = $$(QTDIR)$${DIR_SEPARATOR}plugins
    } else {
      _QT_INCDIR = $$(QT_INCDIR)
      _QT_LIBDIR = $$(QT_LIBDIR)
      _QT_BINDIR = $$(QT_BINDIR)
      _QT_PLUGINDIR = $$(QT_PLUGINDIR)
    }
    !isEmpty (_QT_INCDIR) {
        QMAKE_INCDIR_QT = $$_QT_INCDIR
    }
    !isEmpty (_QT_LIBDIR) {
        QMAKE_LIBDIR_QT = $$_QT_LIBDIR
    }
}

#
# Windows specific configuration
#
win32 {
    INCLUDEPATH += libs/win32/include libs/win32/include/ykpers-1
    HEADERS += src/crandom.h
    SOURCES += src/crandom.cpp

    # The application icon
    RC_FILE = resources/win/resources.rc

    # The application dependencies
    !contains(QMAKE_TARGET.arch, x86_64) {
        message("Windows x86 build")

        LIBS += $$quote(-L./libs/win32/bin) -llibyubikey-0 -llibykpers-1-1
    } else {
        message("Windows x86_64 build")

        LIBS += $$quote(-L./libs/win64/bin) -llibyubikey-0 -llibykpers-1-1
    }

    LIBS += $$quote(-L$$_QT_BINDIR) $$quote(-L$$_QT_LIBDIR)

    CONFIG(debug, debug|release) {
        LIB_FILES += \
             $$_QT_BINDIR$${DIR_SEPARATOR}Qt5Cored.dll \
             $$_QT_BINDIR$${DIR_SEPARATOR}Qt5Guid.dll \
             $$_QT_BINDIR$${DIR_SEPARATOR}Qt5Widgetsd.dll \
             $$_QT_BINDIR$${DIR_SEPARATOR}Qt5Testd.dll \
             $$_QT_PLUGINDIR$${DIR_SEPARATOR}platforms$${DIR_SEPARATOR}qwindowsd.dll \
             $$_QT_PLUGINDIR$${DIR_SEPARATOR}imageformats$${DIR_SEPARATOR}qmngd.dll \
             $$_QT_PLUGINDIR$${DIR_SEPARATOR}accessible$${DIR_SEPARATOR}qtaccessiblewidgetsd.dll
    } else {
        LIB_FILES += \
             $$_QT_BINDIR$${DIR_SEPARATOR}Qt5Core.dll \
             $$_QT_BINDIR$${DIR_SEPARATOR}Qt5Gui.dll \
             $$_QT_BINDIR$${DIR_SEPARATOR}Qt5Widgets.dll \
             $$_QT_PLUGINDIR$${DIR_SEPARATOR}platforms$${DIR_SEPARATOR}qwindows.dll \
             $$_QT_PLUGINDIR$${DIR_SEPARATOR}imageformats$${DIR_SEPARATOR}qmng.dll \
             $$_QT_PLUGINDIR$${DIR_SEPARATOR}accessible$${DIR_SEPARATOR}qtaccessiblewidgets.dll
    }

    LIB_FILES += \
        $$_QT_BINDIR$${DIR_SEPARATOR}libgcc_s_dw2-1.dll \
        $$_QT_BINDIR$${DIR_SEPARATOR}libwinpthread-1.dll \
        $$_QT_BINDIR$${DIR_SEPARATOR}libstdc++-6.dll \
        $$_QT_BINDIR$${DIR_SEPARATOR}icuin52.dll \
        $$_QT_BINDIR$${DIR_SEPARATOR}icuuc52.dll \
        $$_QT_BINDIR$${DIR_SEPARATOR}icudt52.dll \
        libs$${DIR_SEPARATOR}win32$${DIR_SEPARATOR}bin$${DIR_SEPARATOR}libjson-c-2.dll \
        libs$${DIR_SEPARATOR}win32$${DIR_SEPARATOR}bin$${DIR_SEPARATOR}libyubikey-0.dll \
        libs$${DIR_SEPARATOR}win32$${DIR_SEPARATOR}bin$${DIR_SEPARATOR}libykpers-1-1.dll

    isEmpty(TIMESTAMP_URL):TIMESTAMP_URL = 'http://timestamp.verisign.com/scripts/timstamp.dll'

    LIB_FILES_WIN = $${LIB_FILES}
    TARGET_DIR_WIN = $${DESTDIR}
    for(FILE, LIB_FILES_WIN) {
        QMAKE_POST_LINK +=$$quote($$QMAKE_COPY $${FILE} $${TARGET_DIR_WIN}$$escape_expand(\\n\\t))
    }
    LICENSE_DIR = $${TARGET_DIR_WIN}$${DIR_SEPARATOR}licenses
    QMAKE_POST_LINK += $$quote($$QMAKE_MKDIR $${LICENSE_DIR}$$escape_expand(\\n\\t))
    BASEDIR = libs$${DIR_SEPARATOR}win32$${DIR_SEPARATOR}licenses$${DIR_SEPARATOR}
    for(FILE, LICENSEFILES) {
        QMAKE_POST_LINK += $$quote($$QMAKE_COPY $${BASEDIR}$${FILE} $${LICENSE_DIR}$$escape_expand(\\n\\t))
    }
    QMAKE_POST_LINK += $$quote($$QMAKE_COPY COPYING $${LICENSE_DIR}$${DIR_SEPARATOR}yubikey-personalization-gui.txt$$escape_expand(\\n\\t))
    sign_binaries {
        _PVK_FILE = $$(PVK_FILE)
        _SPC_FILE = $$(SPC_FILE)
        isEmpty(_PVK_FILE) {
            error("Must have a pvk file to sign (PVK_FILE env variable).")
        }
        isEmpty(_SPC_FILE) {
            error("Must have a spc file to sign (SPC_FILE env variable).")
        }

        # sign all Yubico binaries
        SIGN_FILES = $${TARGET}.exe \
            libyubikey-0.dll \
            libykpers-1-1.dll

        for(FILE, SIGN_FILES) {
            QMAKE_POST_LINK += $$quote("signcode -spc $$(SPC_FILE) -v $$(PVK_FILE) -a sha1 -$ commercial -n '$${APP_NAME}' -i 'http://www.yubico.com' -t $${TIMESTAMP_URL} $${TARGET_DIR_WIN}$${DIR_SEPARATOR}$${FILE}"$$escape_expand(\\n\\t))
        }
    }
    build_installer {
        QMAKE_POST_LINK += $$quote("makensis -DYKPERS_VERSION=$${VERSION} installer/win-nsis/ykpers.nsi"$$escape_expand(\\n\\t))
        sign_binaries {
            QMAKE_POST_LINK += $$quote("signcode -spc $$(SPC_FILE) -v $$(PVK_FILE) -a sha1 -$ commercial -n '$${APP_NAME} Installer' -i 'http://www.yubico.com' -t '$${TIMESTAMP_URL}' $${TARGET_DIR_WIN}$${DIR_SEPARATOR}$${TARGET}-$${VERSION}.exe"$$escape_expand(\\n\\t))
        }
    }
}

#
# *nix specific configuration
#
unix:!macx|force_pkgconfig {
    message("Unix build")

    LIBS += -lyubikey

    CONFIG += link_pkgconfig
    PKGCONFIG += ykpers-1

    QMAKE_CXXFLAGS += $$(CXXFLAGS)
    QMAKE_LFLAGS += $$(LDFLAGS)
}

#
# MacOS X specific configuration
#
macx:!force_pkgconfig {
    message("Mac build")

    INCLUDEPATH += libs/macx/include libs/macx/include/ykpers-1
    LIBS += libs/macx/lib/libykpers-1.dylib libs/macx/lib/libyubikey.dylib

    CONFIG += x86_64

    DEFINES += QT_MAC_USE_COCOA

    _QT_LIBDIR = $$[QT_INSTALL_LIBS]
    _QT_PLUGINDIR = $$[QT_INSTALL_PLUGINS]

    for_store {
        QMAKE_CFLAGS += -gdwarf-2
        QMAKE_CXXFLAGS += -gdwarf-2

        isEmpty(PACKAGE_SIGN_IDENTITY):PACKAGE_SIGN_IDENTITY = '3rd Party Mac Developer Application'
        isEmpty(INSTALLER_SIGN_IDENTITY):INSTALLER_SIGN_IDENTITY = '3rd Party Mac Developer Installer'
    } else {
        isEmpty(PACKAGE_SIGN_IDENTITY):PACKAGE_SIGN_IDENTITY = 'Developer ID Application'
        isEmpty(INSTALLER_SIGN_IDENTITY):INSTALLER_SIGN_IDENTITY = 'Developer ID Installer'
    }

    # The application dependencies
    LIBS += $$_SDK/System/Library/Frameworks/CoreFoundation.framework/Versions/A/CoreFoundation
    LIBS += $$_SDK/System/Library/Frameworks/IOKit.framework/Versions/A/IOKit

    # The application executable name
    TARGET = $$APP_NAME
    TARGET_MAC = $${TARGET}
    TARGET_MAC ~= s, ,\\ ,g

    # The application icon
    ICON = resources/mac/Yubico.icns

    BUILD = $$(BUILD)
    isEmpty(BUILD) {
        BUILD = 1
    }

    # Copy required resources into the final app bundle and
    # put the current version number into Info.plist
    QMAKE_POST_LINK += $$quote(mkdir -p $${DESTDIR}/$${TARGET_MAC}.app/Contents/Resources && \
        cp -R resources/mac/Yubico.icns $${DESTDIR}/$${TARGET_MAC}.app/Contents/Resources/. && \
        cp resources/mac/qt.conf $${DESTDIR}/$${TARGET_MAC}.app/Contents/Resources/. && \
        sed -e \'s|@@version@@|$$VERSION|g\' -e \'s|@@build@@|$$BUILD|g\' \
        < resources/mac/Info.plist.in  > $${DESTDIR}/$${TARGET_MAC}.app/Contents/Info.plist)

    # copy the QT libraries into our bundle
    _BASEDIR = $${DESTDIR}/$${TARGET_MAC}.app/Contents
    _LIBDIR = $${_BASEDIR}/Frameworks
    _PLUGINDIR = $${_BASEDIR}/PlugIns
    QMAKE_POST_LINK += $$quote( && mkdir -p $$_LIBDIR && \
        cp $$_QT_LIBDIR/QtCore.framework/Versions/5/QtCore $$_LIBDIR && \
        cp $$_QT_LIBDIR/QtGui.framework/Versions/5/QtGui $$_LIBDIR && \
        cp $$_QT_LIBDIR/QtWidgets.framework/Versions/5/QtWidgets $$_LIBDIR && \
        cp $$_QT_LIBDIR/QtPrintSupport.framework/Versions/5/QtPrintSupport $$_LIBDIR && \
        mkdir -p $$_PLUGINDIR/imageformats && \
        cp -R $$_QT_PLUGINDIR/imageformats/libqmng.dylib $$_PLUGINDIR/imageformats && \
        mkdir -p $$_PLUGINDIR/accessible && \
        cp -R $$_QT_PLUGINDIR/accessible/libqtaccessiblewidgets.dylib $$_PLUGINDIR/accessible && \
        mkdir -p $$_PLUGINDIR/platforms && \
        cp -R $$_QT_PLUGINDIR/platforms/libqcocoa.dylib $$_PLUGINDIR/platforms)

    # copy libykpers and friends
    QMAKE_POST_LINK += $$quote( && mkdir -p $$_LIBDIR && \
        cp libs/macx/lib/libyubikey.0.dylib $$_LIBDIR && \
        cp libs/macx/lib/libykpers-1.1.dylib $$_LIBDIR && \
        cp libs/macx/lib/libjson-c.2.dylib $$_LIBDIR)

    _LICENSEDIR = $${_BASEDIR}/licenses
    QMAKE_POST_LINK += $$quote(&& mkdir -p $$_LICENSEDIR && \
        cp COPYING $$_LICENSEDIR/yubikey-personalization-gui.txt)
    for(FILE, LICENSEFILES) {
        QMAKE_POST_LINK += $$quote(&& cp libs/macx/licenses/$${FILE} $$_LICENSEDIR)
    }

    # fixup all library paths..
    _BASE = $$quote(@executable_path/../Frameworks)
    _LIBBASE = $$quote(@executable_path/../lib)
    _QTCORE = $$quote($${_QT_LIBDIR}/QtCore.framework/Versions/5/QtCore)
    _QTGUI = $$quote($${_QT_LIBDIR}/QtGui.framework/Versions/5/QtGui)
    _QTWIDGETS = $$quote($${_QT_LIBDIR}/QtWidgets.framework/Versions/5/QtWidgets)
    _QTPRINTSUPPORT = $$quote($${_QT_LIBDIR}/QtPrintSupport.framework/Versions/5/QtPrintSupport)
    isEmpty(_TARGET_ARCH) {
        _INSTALL_NAME_TOOL = install_name_tool
    } else {
        _INSTALL_NAME_TOOL = $$(TARGET_ARCH)-install_name_tool
    }
    QMAKE_POST_LINK += $$quote( && $$_INSTALL_NAME_TOOL -change $$_QTCORE $$_BASE/QtCore $$_BASEDIR/MacOS/$$TARGET_MAC && \
        $$_INSTALL_NAME_TOOL -change $$_QTGUI $$_BASE/QtGui $$_BASEDIR/MacOS/$$TARGET_MAC && \
        $$_INSTALL_NAME_TOOL -change $$_QTWIDGETS $$_BASE/QtWidgets $$_BASEDIR/MacOS/$$TARGET_MAC && \
        $$_INSTALL_NAME_TOOL -change $$_QTPRINTSUPPORT $$_BASE/QtPrintSupport $$_BASEDIR/MacOS/$$TARGET_MAC && \
        $$_INSTALL_NAME_TOOL -change $$_LIBBASE/libykpers-1.1.dylib $$_BASE/libykpers-1.1.dylib $$_BASEDIR/MacOS/$$TARGET_MAC && \
        $$_INSTALL_NAME_TOOL -change $$_LIBBASE/libyubikey.0.dylib $$_BASE/libyubikey.0.dylib $$_BASEDIR/MacOS/$$TARGET_MAC && \
        $$_INSTALL_NAME_TOOL -change $$_LIBBASE/libyubikey.0.dylib $$_BASE/libyubikey.0.dylib $$_LIBDIR/libykpers-1.1.dylib && \
        $$_INSTALL_NAME_TOOL -change $$_LIBBASE/libjson-c.2.dylib $$_BASE/libjson-c.2.dylib $$_LIBDIR/libykpers-1.1.dylib && \
        $$_INSTALL_NAME_TOOL -id $$_BASE/QtCore $$_LIBDIR/QtCore && \
        $$_INSTALL_NAME_TOOL -change $$_QTCORE $$_BASE/QtCore $$_LIBDIR/QtGui && \
        $$_INSTALL_NAME_TOOL -id $$_BASE/QtGui $$_LIBDIR/QtGui && \
        $$_INSTALL_NAME_TOOL -change $$_QTCORE $$_BASE/QtCore $$_LIBDIR/QtWidgets && \
        $$_INSTALL_NAME_TOOL -change $$_QTGUI $$_BASE/QtGui $$_LIBDIR/QtWidgets && \
        $$_INSTALL_NAME_TOOL -id $$_BASE/QtWidgets $$_LIBDIR/QtWidgets && \
        $$_INSTALL_NAME_TOOL -change $$_QTCORE $$_BASE/QtCore $$_LIBDIR/QtPrintSupport && \
        $$_INSTALL_NAME_TOOL -change $$_QTGUI $$_BASE/QtGui $$_LIBDIR/QtPrintSupport && \
        $$_INSTALL_NAME_TOOL -change $$_QTWIDGETS $$_BASE/QtWidgets $$_LIBDIR/QtPrintSupport && \
        $$_INSTALL_NAME_TOOL -id $$_BASE/QtPrintSupport $$_LIBDIR/QtPrintSupport && \
        $$_INSTALL_NAME_TOOL -change $$_QTCORE $$_BASE/QtCore $$_PLUGINDIR/imageformats/libqmng.dylib && \
        $$_INSTALL_NAME_TOOL -change $$_QTGUI $$_BASE/QtGui $$_PLUGINDIR/imageformats/libqmng.dylib && \
        $$_INSTALL_NAME_TOOL -change $$_QTCORE $$_BASE/QtCore $$_PLUGINDIR/accessible/libqtaccessiblewidgets.dylib && \
        $$_INSTALL_NAME_TOOL -change $$_QTWIDGETS $$_BASE/QtWidgets $$_PLUGINDIR/accessible/libqtaccessiblewidgets.dylib && \
        $$_INSTALL_NAME_TOOL -change $$_QTGUI $$_BASE/QtGui $$_PLUGINDIR/accessible/libqtaccessiblewidgets.dylib && \
        $$_INSTALL_NAME_TOOL -change $$_QTCORE $$_BASE/QtCore $$_PLUGINDIR/platforms/libqcocoa.dylib && \
        $$_INSTALL_NAME_TOOL -change $$_QTWIDGETS $$_BASE/QtWidgets $$_PLUGINDIR/platforms/libqcocoa.dylib && \
        $$_INSTALL_NAME_TOOL -change $$_QTGUI $$_BASE/QtGui $$_PLUGINDIR/platforms/libqcocoa.dylib && \
        $$_INSTALL_NAME_TOOL -change $$_QTPRINTSUPPORT $$_BASE/QtPrintSupport $$_PLUGINDIR/platforms/libqcocoa.dylib)

    build_installer {
        # the productbuild path doesn't work pre 10.8
        for_store {
            _INSTALLER_CMD = "productbuild --sign \'$$INSTALLER_SIGN_IDENTITY\' --component $${DESTDIR}/$${TARGET_MAC}.app /Applications/ $${DESTDIR}/$${TARGET_MAC}-$${VERSION}.pkg"
        } else {
            _INSTALLER_CMD = "rm -rf $${DESTDIR}/temp && \
                mkdir -p $${DESTDIR}/temp/ && \
                cp -R $${DESTDIR}/$${TARGET_MAC}.app $${DESTDIR}/temp && \
                pkgbuild --sign \'$$INSTALLER_SIGN_IDENTITY\' --root ${DESTDIR}/temp/ --component-plist resources/mac/installer.plist --install-location '/Applications/' $${DESTDIR}/$${TARGET_MAC}-$${VERSION}.pkg"
        }
        QMAKE_POST_LINK += $$quote( && \
            codesign --deep -s \'$$PACKAGE_SIGN_IDENTITY\' $${DESTDIR}/$${TARGET_MAC}.app \
            --entitlements resources/mac/Entitlements.plist && \
            $$_INSTALLER_CMD)
    }
}

#
# Additional cleanup to be performed
#
win32 {
    TARGET_DIR_WIN = $${DESTDIR}

    QMAKE_CLEAN += $${TARGET_DIR_WIN}$${DIR_SEPARATOR}*.exe \
                   $${TARGET_DIR_WIN}$${DIR_SEPARATOR}*.dll \
                   $${TARGET_DIR_WIN}$${DIR_SEPARATOR}*.exe.bak
} else:macx {
    QMAKE_CLEAN += -r $${DESTDIR}/*.app $${DESTDIR}/*.pkg $${DESTDIR}/*.dmg
} else {
    QMAKE_CLEAN += -r $${DESTDIR}/*
}
[warewolf@xanatos yubikey-personalization-gui-3.1.17]$ qmake-qt4 && make
Project MESSAGE: Release build
Project MESSAGE: Unix build
uic src/ui/toolpage.ui
uic src/ui/staticpage.ui
uic src/ui/settingpage.ui
uic src/ui/otppage.ui
uic src/ui/oathpage.ui
uic src/ui/mainwindow.ui
uic src/ui/helpbox.ui
uic src/ui/confirmbox.ui
uic src/ui/chalresppage.ui
uic src/ui/aboutpage.ui
uic src/ui/diagnostics.ui
uic src/ui/yubiaccbox.ui
compiling src/main.cpp
compiling src/ui/toolpage.cpp
compiling src/ui/staticpage.cpp
compiling src/ui/settingpage.cpp
compiling src/ui/scanedit.cpp
compiling src/ui/otppage.cpp
compiling src/ui/oathpage.cpp
compiling src/ui/mainwindow.cpp
compiling src/ui/helpbox.cpp
compiling src/ui/confirmbox.cpp
compiling src/ui/chalresppage.cpp
compiling src/ui/aboutpage.cpp
compiling src/ui/yubiaccbox.cpp
compiling src/ui/diagnostics.cpp
compiling src/yubikeywriter.cpp
compiling src/yubikeyutil.cpp
compiling src/yubikeylogger.cpp
compiling src/yubikeyfinder.cpp
compiling src/yubikeyconfig.cpp
moc src/ui/toolpage.h
compiling build/release/MOCFiles/moc_toolpage.cpp
moc src/ui/staticpage.h
compiling build/release/MOCFiles/moc_staticpage.cpp
moc src/ui/settingpage.h
compiling build/release/MOCFiles/moc_settingpage.cpp
moc src/ui/otppage.h
compiling build/release/MOCFiles/moc_otppage.cpp
moc src/ui/oathpage.h
compiling build/release/MOCFiles/moc_oathpage.cpp
moc src/ui/mainwindow.h
compiling build/release/MOCFiles/moc_mainwindow.cpp
moc src/ui/helpbox.h
compiling build/release/MOCFiles/moc_helpbox.cpp
moc src/ui/confirmbox.h
compiling build/release/MOCFiles/moc_confirmbox.cpp
moc src/ui/chalresppage.h
compiling build/release/MOCFiles/moc_chalresppage.cpp
moc src/ui/aboutpage.h
compiling build/release/MOCFiles/moc_aboutpage.cpp
moc src/ui/diagnostics.h
compiling build/release/MOCFiles/moc_diagnostics.cpp
moc src/ui/yubiaccbox.h
compiling build/release/MOCFiles/moc_yubiaccbox.cpp
moc src/yubikeywriter.h
compiling build/release/MOCFiles/moc_yubikeywriter.cpp
moc src/yubikeylogger.h
compiling build/release/MOCFiles/moc_yubikeylogger.cpp
moc src/yubikeyfinder.h
compiling build/release/MOCFiles/moc_yubikeyfinder.cpp
moc src/yubikeyconfig.h
compiling build/release/MOCFiles/moc_yubikeyconfig.cpp
rcc resources/resources.qrc
compiling build/release/RCCFiles/qrc_resources.cpp
linking build/release/yubikey-personalization-gui
ey-personalization-guikey-personalization-gui-3.1.17]$ ldd ./build/release/yubik 
        linux-vdso.so.1 =>  (0x00007fff347ac000)
        libyubikey.so.0 => /lib64/libyubikey.so.0 (0x0000003f5d600000)
        libykpers-1.so.1 => /lib64/libykpers-1.so.1 (0x0000003067800000)
        libQtGui.so.4 => /lib64/libQtGui.so.4 (0x00000030d0400000)
        libQtCore.so.4 => /lib64/libQtCore.so.4 (0x00000030cc000000)
        libpthread.so.0 => /lib64/libpthread.so.0 (0x00000030c6800000)
        libstdc++.so.6 => /lib64/libstdc++.so.6 (0x00000030cf800000)
        libm.so.6 => /lib64/libm.so.6 (0x00000030c7000000)
        libgcc_s.so.1 => /lib64/libgcc_s.so.1 (0x00000030c8c00000)
        libc.so.6 => /lib64/libc.so.6 (0x00000030c6400000)
        libusb-1.0.so.0 => /lib64/libusb-1.0.so.0 (0x000000306a400000)
        libgthread-2.0.so.0 => /lib64/libgthread-2.0.so.0 (0x00000030cdc00000)
        libglib-2.0.so.0 => /lib64/libglib-2.0.so.0 (0x00000030c9000000)
        libpng16.so.16 => /lib64/libpng16.so.16 (0x00000030cb000000)
        libz.so.1 => /lib64/libz.so.1 (0x00000030c7400000)
        libfreetype.so.6 => /lib64/libfreetype.so.6 (0x00000030cb800000)
        libgobject-2.0.so.0 => /lib64/libgobject-2.0.so.0 (0x00000030c9c00000)
        libSM.so.6 => /lib64/libSM.so.6 (0x00000030de400000)
        libICE.so.6 => /lib64/libICE.so.6 (0x00000030de000000)
        libXi.so.6 => /lib64/libXi.so.6 (0x00000030d4000000)
        libXrender.so.1 => /lib64/libXrender.so.1 (0x00000030cd000000)
        libXrandr.so.2 => /lib64/libXrandr.so.2 (0x00000030ce000000)
        libXfixes.so.3 => /lib64/libXfixes.so.3 (0x00000030d0000000)
        libXcursor.so.1 => /lib64/libXcursor.so.1 (0x00000030d5c00000)
        libXinerama.so.1 => /lib64/libXinerama.so.1 (0x00000030cd400000)
        libfontconfig.so.1 => /lib64/libfontconfig.so.1 (0x00000030ccc00000)
        libXext.so.6 => /lib64/libXext.so.6 (0x00000030cb400000)
        libX11.so.6 => /lib64/libX11.so.6 (0x00000030ca400000)
        libdl.so.2 => /lib64/libdl.so.2 (0x00000030c6c00000)
        librt.so.1 => /lib64/librt.so.1 (0x00000030c8400000)
        /lib64/ld-linux-x86-64.so.2 (0x00000030c6000000)
        libudev.so.1 => /lib64/libudev.so.1 (0x00007fb096c55000)
        libffi.so.6 => /lib64/libffi.so.6 (0x00000030c9400000)
        libuuid.so.1 => /lib64/libuuid.so.1 (0x00000030d3000000)
        libexpat.so.1 => /lib64/libexpat.so.1 (0x00000030cbc00000)
        libxcb.so.1 => /lib64/libxcb.so.1 (0x00000030ca800000)
        libselinux.so.1 => /lib64/libselinux.so.1 (0x00000030c8000000)
        libXau.so.6 => /lib64/libXau.so.6 (0x00000030cac00000)
        libpcre.so.1 => /lib64/libpcre.so.1 (0x00000030c7c00000)
        liblzma.so.5 => /lib64/liblzma.so.5 (0x00000030c7800000)
ersonalization-guiyubikey-personalization-gui-3.1.17]$ ./build/release/yubikey-p 
[warewolf@xanatos yubikey-personalization-gui-3.1.17]$ exit

Script done on Mon Nov 10 08:02:21 2014