Clojure macro: as-some->

as_some.clj

;; This macro is also available in: https://github.com/wdhowe/clj-contrib

(defmacro as-some->
  "as->, with the nil checking of some->.
   Binds name to expr. When name is not nil, evaluates the first
   form in the lexical context of that binding. When that result
   is not nil, then binds name to result, repeating for each
   successive form."
  [expr name & forms]
  (let [steps (map (fn [step] `(if (nil? ~name) nil ~step))
                   forms)]
    `(let [~name ~expr
           ~@(interleave (repeat name) (butlast steps))]
       ~(if (empty? steps)
          name
          (last steps)))))

(comment
  ;; example 1: successfully returns the string.
  (def things {:one 1, :two 2})
  (as-some-> things mythings
             (:one mythings)
             (inc mythings)
             (str "These " mythings " things and more!"))

  ;; example 2: terminates early and returns nil due to the :one key not existing
  (def things {:two 2})
  (as-some-> things mythings
             (:one mythings)
             (inc mythings)
             (str "These " mythings " things and more!")))