FLACS Direction Cosines

DirectionCosines = LAMBDA(xl, yl, [zl], [xt], [yt], [zt],
    SplitString(
        IF(
            OR(ISOMITTED(zl), ISOMITTED(xt), ISOMITTED(yt), ISOMITTED(zt)),
            LET(
                thetaz, xl,
                phi, yl,
                1 * SIN(RADIANS(thetaz)) * COS(RADIANS(phi)) & "," &
                1 * SIN(RADIANS(thetaz)) * SIN(RADIANS(phi)) & "," &
                1 * COS(RADIANS(thetaz)) & "," & thetaz & "," & 
                if(
                    phi >= 0,
                    phi,
                    360 + phi
                )
            ),
            LET(
                magx, xt - xl,
                magy, yt - yl,
                magz, zt - zl,
                mag, SQRT(magx ^ 2 + magy ^ 2 + magz ^ 2),
                magx / mag & "," & magy / mag & "," & magz / mag & "," &
                DEGREES(ACOS(magz / mag / 1)) & "," &
                IF(
                    magy >= 0,
                    DEGREES(ACOS(magx / mag / (1 * SIN(ACOS(magz / mag / 1))))),
                    360 - DEGREES(ACOS(magx / mag / (1 * SIN(ACOS(magz / mag / 1)))))
                )
            )
        ),
        ","
    )
);

SplitString = LAMBDA(text, delim, [indexInt],
    IF(
        ISOMITTED(indexInt),
        TRANSPOSE(
            FILTERXML(
                "<x><y>" & SUBSTITUTE(text, delim, "</y><y>") & "</y></x>",
                "//y"
            )
        ),
        INDEX(
            TRANSPOSE(
                FILTERXML(
                    "<x><y>" & SUBSTITUTE(text, delim, "</y><y>") & "</y></x>",
                    "//y"
                )
            ),
            1,
            indexInt
        )
    )
);