batch file generate apk file and notification

::wendell on 2023/3/2
::使用utf-8编码，编码为65001
chcp 65001

@echo off
echo "----------------"
echo "开始apk打包!"
@REM echo 程序开始时间：%Time%
echo 开始时间是%time:~0,2%点%time:~3,2%分%time:~6,2%秒
echo.
set startTime=%time%


::/b  同一个窗口执行 /w 等待cmd执行结束 /c 新开的窗口会自动关闭
::start /b /w cmd /k "cd /d D:\Android\project\xxx && gradlew assembleUatRelease"
start cmd  /c  "cd /d D:\Android\project\xxx & title PackageAPK && gradlew assembleUatRelease"


:waittofinish
echo "打包进行中，请稍等"
timeout /T 2 /nobreak >nul
tasklist.exe /fi "WINDOWTITLE eq PackageAPK*" | find ":" >nul
if errorlevel 1 goto waittofinish

echo.
echo 结束时间是%time:~0,2%点%time:~3,2%分%time:~6,2%秒
set endTime=%time%

call :formatTime intervalTime

echo "结束apk打包!"
echo "----------------"
mshta vbscript:CreateObject("Wscript.Shell").popup(Replace("打包结束!\n结束时间%Time%\n耗时%intervalTime%","\n",vbCrLf),60,"通知",64)(window.close)
@REM mshta vbscript:msgbox(Replace("打包结束!\n结束时间%Time%\n耗时%intervalTime%","\n",vbCrLf),0,"通知")(window.close)
pause
::exit


:formatTime
set /a h1=%startTime:~0,2%
set /a m1=1%startTime:~3,2%-100
set /a s1=1%startTime:~6,2%-100
set /a h2=%endTime:~0,2%
set /a m2=1%endTime:~3,2%-100
set /a s2=1%endTime:~6,2%-100
if %h2% LSS %h1% set /a h2=%h2%+24
set /a ts1=%h1%*3600+%m1%*60+%s1%
set /a ts2=%h2%*3600+%m2%*60+%s2%
set /a ts=%ts2%-%ts1%
set /a h=%ts%/3600
set /a m=(%ts%-%h%*3600)/60
set /a s=%ts%%%60
set intervalTime=%h%小时%m%分%s%秒
set "%~1=%intervalTime%"
goto :eof