PKGBUILD of ibus-git

ibus.install

post_install() {
    gtk-query-immodules-2.0 --update-cache
    gtk-query-immodules-3.0 --update-cache
    gtk-update-icon-cache -fq -t /usr/share/icons/hicolor

    glib-compile-schemas /usr/share/glib-2.0/schemas
}

post_upgrade() {
    post_install
}

post_remove() {
    post_install
}

PKGBUILD

# Maintainer: Limao Luo <[email protected]>
# Contributor: Jekyll Wu <[email protected]>
# Contributor: riverscn <[email protected]>
# Contributor: Lee.MaRS <[email protected]>
# Contributor: Techlvie Zheng <[email protected]>

_pkgname=ibus
pkgname=${_pkgname}-git
pkgver=1.5.4.r15.g7587b8e
pkgrel=1
pkgdesc="Next Generation Input Bus for Linux"
arch=('i686' 'x86_64')
license=(LGPL2.1)
url=http://${_pkgname}.googlecode.com
depends=('hicolor-icon-theme' 'gtk2' 'gtk3' 'libnotify' 'python2-gobject')
makedepends=('gobject-introspection' 'gnome-common' 'vala' 'dconf' 'gconf' 'intltool' 'iso-codes')
provides=(${_pkgname} libibus)
conflicts=(${_pkgname} libibus)
options=(!emptydirs !libtool)
install=${_pkgname}.install
source=($pkgname::git://github.com/${_pkgname}/${_pkgname}.git)
sha1sums=('SKIP')

pkgver() {
    cd ${pkgname}
    git describe --tags --long --always | sed -E 's/([^-]*-g)/r\1/;s|-|.|g'
}

build() {
    cd ${pkgname}
    export PYTHON=python2
    ./autogen.sh \
        --prefix=/usr \
        --libexecdir=/usr/lib/${_pkgname} \
        --sysconfdir=/etc \
        --enable-dconf \
        --disable-gconf \
        --disable-memconf \
        --enable-python-library

    make
}

package() {
    cd ${pkgname}
    make DESTDIR="${pkgdir}" install
}