PKGBUILD of nightingale-git

nightingale.desktop

[Desktop Entry]
Name=Nightingale
Type=Application
Comment=An open-source customizable music player - SVN version
Exec=/opt/nightingale/nightingale
Icon=nightingale
Categories=AudioVideo;Player;

nightingale.install

post_install() {
	update-desktop-database -q
}

post_upgrade() {
	update-desktop-database -q
}

post_remove() {
	update-desktop-database -q
}

op=$1
shift

$op $*

PKGBUILD

# Maintainer: Matt Parnell/ilikenwf
# Contributor: Sam Stuewe <[email protected]>
# Contributor: Techlive Zheng <[email protected]>

_gitname=nightingale-hacking
_branch=sb-trunk-oldxul
pkgname=nightingale-git
pkgver=1.12.1.r3.g020e12a
pkgrel=1
pkgdesc="Community port of Songbird to be more Linux native, up to date, and open."
arch=('i686' 'x86_64')
url="http://getnightingale.com/"
license=('GPL2' 'MPL' 'BSD')
makedepends=('git'
             'zip'
             'unzip'
             'glib2'
             'python'
             'libidl2'
)
depends=('gtk2'
         'libxt'
         'taglib'
         'sqlite3'
         'gstreamer'
         'gst-plugins-bad'
         'gst-plugins-good'
         'gst-plugins-base'
         'gst-plugins-base-libs'
)
conflicts=('nightingale')
provides=('nightingale')
install=nightingale.install
source=("nightingale::git://github.com/nightingale-media-player/${_gitname}.git#branch=${_branch}"
        'nightingale.desktop'
        'http://downloads.sourceforge.net/project/ngale/1.12-Build-Deps/vendor-1.12.zip'
        "http://downloads.sourceforge.net/project/ngale/1.12-Build-Deps/linux-${CARCH}-1.12-20130316-release-final.tar.lzma")
md5sums=('SKIP'
         '7741cc247648e95dd9dad8c953616757'
         '208c81bfd972ae4cb1f350688da304e6')
[[ "${CARCH}" == 'i686' ]] && md5sums+=('c30cc1d763d8c5cc0b0a2ae8216af18b')
[[ "${CARCH}" == 'x86_64' ]] && md5sums+=('a9b47ef0b21106f6b51231046e1758d1')

pkgver() {
	cd "nightingale"
	git describe --tags --long --always | sed -E 's/nightingale.//;s/([^-]*-g)/r\1/;s|-|.|g'
}

prepare() {
	cd "${srcdir}/nightingale/dependencies"

	# just in case we already have the symlinks there...to avoid errors
	ln -sf "${srcdir}/linux-$CARCH" ./
	ln -sf "${srcdir}/vendor" ./

	# our gstreamer path, since we use system libs :)
	export GST_PLUGIN_PATH="/usr/lib/gstreamer-0.10"

	# use our own gstreamer libs
	echo 'ac_add_options --with-media-core=gstreamer-system' >> "${srcdir}/nightingale/nightingale.config"
	echo 'ac_add_options --with-gstreamer-1.0\n' >> "${srcdir}/nightingale/nightingale.config"
}

build() {
	cd "${srcdir}/nightingale"

	make
}

package() {
	install -d "${pkgdir}/opt/nightingale"

	cd "${srcdir}/nightingale/compiled/dist"
	sed -i 's/0\.10/1\.0/g' nightingale # hack for now to make the launcher work properly
	cp -a --no-preserve=ownership * "${pkgdir}/opt/nightingale/"

	chmod -R a+r "${pkgdir}/opt/nightingale"
	chmod 755 "${pkgdir}/opt/nightingale/nightingale-bin"
	chmod 755 "${pkgdir}/opt/nightingale/xulrunner/xulrunner-bin"

	install -D "${srcdir}/nightingale/compiled/dist/chrome/icons/default/default.xpm" \
		"${pkgdir}/usr/share/pixmaps/nightingale.xpm"
	install -D -m644 "${srcdir}/nightingale.desktop" \
		"${pkgdir}/usr/share/applications/nightingale.desktop"

	find "${pkgdir}" -type d -name .git -exec rm -r '{}' +
}