raymarching noise

raymarch_noise.hlsl

struct Functions {

    // 3d gradient noise from iq
    // https://www.shadertoy.com/view/Xsl3Dl
    float3 hash( float3 p )
    {
        p = float3( dot(p,float3(127.1,311.7, 74.7)),
                    dot(p,float3(269.5,183.3,246.1)),
                    dot(p,float3(113.5,271.9,124.6)));

        return -1.0 + 2.0*frac(sin(p)*43758.5453123);
    }

    float noise( float3 p )
    {
        float3 i = floor( p );
        float3 f = frac( p );


        float3 u = f*f*(3.0-2.0*f); 

        return lerp( lerp( lerp( dot( hash( i + float3(0.0,0.0,0.0) ), f - float3(0.0,0.0,0.0) ), 
                            dot( hash( i + float3(1.0,0.0,0.0) ), f - float3(1.0,0.0,0.0) ), u.x),
                        lerp( dot( hash( i + float3(0.0,1.0,0.0) ), f - float3(0.0,1.0,0.0) ), 
                            dot( hash( i + float3(1.0,1.0,0.0) ), f - float3(1.0,1.0,0.0) ), u.x), u.y),
                    lerp( lerp( dot( hash( i + float3(0.0,0.0,1.0) ), f - float3(0.0,0.0,1.0) ), 
                            dot( hash( i + float3(1.0,0.0,1.0) ), f - float3(1.0,0.0,1.0) ), u.x),
                        lerp( dot( hash( i + float3(0.0,1.0,1.0) ), f - float3(0.0,1.0,1.0) ), 
                            dot( hash( i + float3(1.0,1.0,1.0) ), f - float3(1.0,1.0,1.0) ), u.x), u.y), u.z );
    }

    // cosine palette from iq
    // https://iquilezles.org/articles/palettes/
    float3 palette( float t, float3 a, float3 b, float3 c, float3 d )
    {
        return a + b*cos( 6.283185*(c*t+d) );
    }


    // smooth maximum
    float smax(float d1, float d2, float k) {
        float h = clamp( 0.5 - 0.5*(d2-d1)/k, 0.0, 1.0 );
        return lerp( d2, d1, h ) + k*h*(1.0-h); 
    }
};

float3 t = float3(input.uv*2.-1.,.55);
float f; float3 p;

Functions func;

for (int i = 0; i++<_iterations;) {
    p = t*f + float3(0,0,_time);
    f += func.smax(func.noise(p),-length(p*float3(1,1,0))+.5,.5)+.1; 
}
f /= 25.;

// colors
float3 c = func.palette(func.noise(p*.5),
    float3(.5,.5,.5),
    float3(.5,.5,.5),
    float3(1.,.8,1.),
    float3(.0,.33,.67))+1.;

// tanh tonemapping trick from @XorDev
output.color = float4(tanh(c*f*2.),1.);