yt-dlp.bat

:: Downloads video from link in clipboard using yt-dlp (+ ffmpeg)
:: winget install yt-dlp.yt-dlp Gyan.FFmpeg

@echo off
:: finds the downloads folder
for /f "delims=" %%a in ('powershell -command "(New-Object -ComObject Shell.Application).NameSpace('shell:Downloads').Self.Path"') do set "DOWNLOADS=%%a"
:: get value from clipboard
for /f "delims=" %%i in ('powershell Get-Clipboard') do set "url=%%i"
:check
yt-dlp.exe -F -S vext "%url%"
if ERRORLEVEL 1 (
	:: if the url is not read from the buffer - enter manually
	set /p url=Enter the url: 
	echo.
	goto check
)
echo.
set num=
set /p num=Enter videoID+audioID (for example 137+140) or leave empty for the best video with the best extension: 
echo.
if not defined num (
	:: For video, mp4 > mov > webm > flv. For audio, m4a > aac > mp3 ...
	yt-dlp.exe -S "ext" "%url%" -P "%DOWNLOADS%" -o "%%(title).50s.%%(ext)s" --no-part
	if ERRORLEVEL 1 (goto check)
) else (
    :: Can be combined with any other params like --download-sections "*00:xx:xx-00:xx:xx"
	yt-dlp.exe -f %num% "%url%" -P "%DOWNLOADS%" -o "%%(title).50s.%%(ext)s" --no-part
	if ERRORLEVEL 1 (goto check)
)
color 27
explorer "%DOWNLOADS%"
timeout 1

Windows 11 x64.

подправил